diff --git a/media-sound/Tauon/Manifest b/media-sound/Tauon/Manifest
index 457cc04cd7..ddf119b1c3 100644
--- a/media-sound/Tauon/Manifest
+++ b/media-sound/Tauon/Manifest
@@ -1,2 +1,3 @@
+DIST Tauon-10.0.1.tar.gz 3265522 BLAKE2B 7e1f624af5d085ee6b1f3abd039bc7f315534ff5440fb9093b35aa36d3d5b1f4af994c52e99511d010ffe0be39cfdd321172b7e421ab78e06ebb21a1cbbf7071 SHA512 ab9997ad542534d61514c9d2c05e395ba5e42f2719905fadb32a09cbbe86b8b2adb0adaca534375e2ef4339ee15abd100edabd2086272f914dffb635d4a0c10e
 DIST Tauon-9.1.1.tar.gz 1782548 BLAKE2B 94ee132145c2f8776f5e7e9948383aebc82417f4ec3dae95e50198993dc3baaa682faeb8fce9285c0100feccc827f3657db92cf2913e2fe2f105f388a45f5001 SHA512 d152f0374284ef1429492d317949b62a53cea85aaac1bcf9d18cb45c1d1591d1bc9eb4fca73f0ea0bbfdc01a5afa0355b45907de6936a7ffcc4a7f86b938312f
 DIST Tauon-9.1.3.tar.gz 3790782 BLAKE2B 09a55ae03476bd1f92c6c2ec1e8435b00d8837346a7927176af163987537ef7390710733174d78f29e1d1e11326c19d80bb47a49eace197eaf5fbcdee2bb6111 SHA512 025d55ffca742f5574bb9949b5fcbdf9dfbeaec83b111b72a8a62e4b7ed066dba1142619f7938a065f780031cea43832994978b7f2f99dc4a7288077196783ef
diff --git a/media-sound/Tauon/Tauon-10.0.1.ebuild b/media-sound/Tauon/Tauon-10.0.1.ebuild
new file mode 100644
index 0000000000..a482892ae2
--- /dev/null
+++ b/media-sound/Tauon/Tauon-10.0.1.ebuild
@@ -0,0 +1,110 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PLOCALES="cs de es fr_FR hu id it ja_JP nb_NO pl pt pt_BR pt_PT ru sv tr zh_CN"
+
+PYTHON_COMPAT=( python3_{12..14} )
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+
+inherit desktop distutils-r1 optfeature plocale xdg
+
+DESCRIPTION="The desktop music player of today!"
+HOMEPAGE="https://tauonmusicbox.rocks/"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_SUBMODULES=()
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Taiko2k/${PN}"
+else
+	SRC_URI="https://github.com/Taiko2k/Tauon/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+PHAZOR_DEPS="
+	dev-libs/miniaudio
+	media-libs/flac:=
+	media-libs/game-music-emu
+	media-libs/libopenmpt
+	media-libs/opus
+	media-libs/opusfile
+	media-libs/libsamplerate
+	media-libs/libvorbis
+	media-sound/mpg123
+	media-sound/wavpack
+	sci-libs/kissfft[-cpu_flags_x86_sse]
+"
+
+DEPEND="
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/musicbrainzngs[${PYTHON_USEDEP}]
+	dev-python/natsort[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pyopengl[${PYTHON_USEDEP}]
+	dev-python/pysdl3[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setproctitle[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	dev-python/unidecode[${PYTHON_USEDEP}]
+	media-video/ffmpeg
+	media-libs/mutagen[${PYTHON_USEDEP}]
+	media-libs/sdl3-image
+
+	${PHAZOR_DEPS}
+"
+
+RDEPEND="
+	${DEPEND}
+
+	dev-libs/libayatana-appindicator
+	media-sound/mpg123-base
+	x11-libs/libnotify
+"
+
+BDEPEND="sys-devel/gettext"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-7.9.0-phazor-build.patch"
+	"${FILESDIR}/${PN}-8.1.0-fix-locale-path.patch"
+)
+
+src_compile() {
+	distutils-r1_src_compile
+
+	build_locale() {
+		msgfmt -o "locale/${1}/LC_MESSAGES/tauon.mo" "locale/${1}/LC_MESSAGES/tauon.po" || die
+	}
+
+	plocale_for_each_locale build_locale
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	install_locale() {
+		insinto "/usr/share/locale/${1}/LC_MESSAGES"
+		doins "locale/${1}/LC_MESSAGES/tauon.mo"
+	}
+
+	plocale_for_each_locale install_locale
+
+	sed -i 's/Exec=tauon/Exec=tauonmb/g' extra/tauonmb.desktop || die
+	domenu extra/tauonmb.desktop
+	doicon -s scalable extra/tauonmb.svg
+
+}
+
+pkg_postinst() {
+	optfeature "Chinese searches support" app-i18n/opencc[python]
+	optfeature "last fm support" dev-python/pylast
+	optfeature "PLEX support" dev-python/plexapi
+	optfeature "Spotify support" dev-python/tekore
+	optfeature "Discord Rich Presence support" dev-python/pypresence
+
+	xdg_pkg_postinst
+}