From 70f4fb66515f241425b88146b3eb061c080638d4 Mon Sep 17 00:00:00 2001
From: Alessandro Barbieri <lssndrbarbieri@gmail.com>
Date: Sat, 9 Apr 2022 16:00:13 +0200
Subject: [PATCH] dev-ml/tar: initial import

Signed-off-by: Alessandro Barbieri <lssndrbarbieri@gmail.com>
---
 dev-ml/tar/Manifest         |  1 +
 dev-ml/tar/metadata.xml     | 15 ++++++++++
 dev-ml/tar/tar-2.0.1.ebuild | 60 +++++++++++++++++++++++++++++++++++++
 3 files changed, 76 insertions(+)
 create mode 100644 dev-ml/tar/Manifest
 create mode 100644 dev-ml/tar/metadata.xml
 create mode 100644 dev-ml/tar/tar-2.0.1.ebuild

diff --git a/dev-ml/tar/Manifest b/dev-ml/tar/Manifest
new file mode 100644
index 0000000000..96729e50ab
--- /dev/null
+++ b/dev-ml/tar/Manifest
@@ -0,0 +1 @@
+DIST tar-2.0.1.tar.gz 26751 BLAKE2B a381c258c75350198c25c105f8ca33f33dd8d946f88cb102186ece414def2fa5e25191c2ed43d5d0e9286a0bc352ffec8b6999d17f18479642900b59f4d1cc17 SHA512 fd2e302497eb673a4e8000d0bcfd9012b1f118021e1d071a7c56cc6652ec6da9c6f755c18aa4b275daf1f722409d71cbb4519285096682344bfa65bbe800cbd1
diff --git a/dev-ml/tar/metadata.xml b/dev-ml/tar/metadata.xml
new file mode 100644
index 0000000000..76d46cfa29
--- /dev/null
+++ b/dev-ml/tar/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>lssndrbarbieri@gmail.com</email>
+    <name>Alessandro Barbieri</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">mirage/ocaml-tar</remote-id>
+  </upstream>
+  <use>
+    <flag name="mirage">Read and write tar format files via MirageOS interfaces</flag>
+    <flag name="unix">Decode and encode tar format files from Unix</flag>
+  </use>
+</pkgmetadata>
diff --git a/dev-ml/tar/tar-2.0.1.ebuild b/dev-ml/tar/tar-2.0.1.ebuild
new file mode 100644
index 0000000000..8ddc49ac34
--- /dev/null
+++ b/dev-ml/tar/tar-2.0.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit dune multiprocessing
+
+MYPN="ocaml-${PN}"
+
+DESCRIPTION="Pure OCaml library to read and write tar files"
+HOMEPAGE="https://github.com/mirage/ocaml-tar"
+SRC_URI="https://github.com/mirage/${MYPN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MYPN}-${PV}"
+
+LICENSE="ISC"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="mirage ocamlopt test unix"
+
+RDEPEND="
+	dev-ml/camlp-streams
+	dev-ml/cstruct
+	dev-ml/re
+	dev-ml/lwt
+
+	mirage? (
+		dev-ml/io-page
+		dev-ml/mirage-block
+		dev-ml/mirage-kv
+		dev-ml/ptime
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-ml/mirage-block-unix
+		>=dev-ml/ounit-2[lwt]
+	)
+"
+
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	test? ( mirage unix )
+"
+
+src_compile() {
+	local pkgs="tar"
+	for u in mirage unix ; do
+		if use ${u} ; then
+			pkgs="${pkgs},tar-${u}"
+		fi
+	done
+	dune build -p "${pkgs}" -j $(makeopts_jobs) || die
+}
+
+src_install() {
+	dune_src_install tar
+	use mirage && dune_src_install tar-mirage
+	use unix && dune_src_install tar-unix
+}