From 70c3292006342ad7464eceab4a5df07e25e5f4f9 Mon Sep 17 00:00:00 2001
From: Patrick Zwerschke <patrick@p5k.org>
Date: Sun, 6 Sep 2026 01:04:05 +0200
Subject: [PATCH] dev-python/rawpy: new package, add 0.27.1

Signed-off-by: Patrick Zwerschke <patrick@p5k.org>
---
 dev-python/rawpy/Manifest            |  1 +
 dev-python/rawpy/metadata.xml        | 12 ++++++++
 dev-python/rawpy/rawpy-0.27.1.ebuild | 44 ++++++++++++++++++++++++++++
 3 files changed, 57 insertions(+)
 create mode 100644 dev-python/rawpy/Manifest
 create mode 100644 dev-python/rawpy/metadata.xml
 create mode 100644 dev-python/rawpy/rawpy-0.27.1.ebuild

diff --git a/dev-python/rawpy/Manifest b/dev-python/rawpy/Manifest
new file mode 100644
index 0000000000..3766a39d72
--- /dev/null
+++ b/dev-python/rawpy/Manifest
@@ -0,0 +1 @@
+DIST rawpy-0.27.1.gh.tar.gz 76018988 BLAKE2B 669b26bb2d0d963f13287a2d2c01927f5ae4501e1b703d71043d53d8fb0f66b1f51ed721d46b7edfafb673705d03ecd8b1c1d97ef061d515414beb0dbb02dcae SHA512 53da8382c80704084b71dab049969a4d0d63db155595443107d1e9383f9c76003dd7d3000e0ceb346e962eaf8c592a51dd99a8afe7f997c69d3e49ae14fb36cc
diff --git a/dev-python/rawpy/metadata.xml b/dev-python/rawpy/metadata.xml
new file mode 100644
index 0000000000..61849ac959
--- /dev/null
+++ b/dev-python/rawpy/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>patrick@p5k.org</email>
+		<name>Patrick Zwerschke</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">letmaik/rawpy</remote-id>
+		<remote-id type="pypi">rawpy</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/rawpy/rawpy-0.27.1.ebuild b/dev-python/rawpy/rawpy-0.27.1.ebuild
new file mode 100644
index 0000000000..44091d5156
--- /dev/null
+++ b/dev-python/rawpy/rawpy-0.27.1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..15} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python wrapper for LibRaw, RAW image processing"
+HOMEPAGE="https://github.com/letmaik/rawpy https://pypi.org/project/rawpy/"
+SRC_URI="https://github.com/letmaik/rawpy/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND=">=media-libs/libraw-0.21:="
+RDEPEND="${DEPEND}
+	dev-python/numpy[${PYTHON_USEDEP}]"
+BDEPEND="dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	virtual/pkgconfig
+	test? (
+		dev-python/imageio[${PYTHON_USEDEP}]
+		dev-python/scikit-image[${PYTHON_USEDEP}]
+	)"
+
+EPYTEST_PLUGINS=()
+EPYTEST_IGNORE=(
+	test_mypy.py
+	test_stubtest.py
+)
+distutils_enable_tests pytest
+
+python_configure_all() {
+	export RAWPY_USE_SYSTEM_LIBRAW=1
+}
+
+python_test() {
+	cd test || die
+	epytest
+}