Move {dev-python → dev-util}/pifpaf

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-util/pifpaf/Manifest

@@ -0,0 +1 @@
+DIST pifpaf-3.1.5.tar.gz 189903 BLAKE2B 5742e995feeb91af41db20cc605e8a5f5f21f63281d4f66ba8b108310a88d716ab4be0a43e0371f10e7f3f42b693953b3344c648458999348b914e03abe462c8 SHA512 4e0f70740f8260cb3cf801ea97f1fa30e6b87cfc4112b5482389d0635e76bbc7f1561945397e4e6586116c49d11b1e8f721dd61dca82668833bf224f9ba3e94f

dev-util/pifpaf/metadata.xml

@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>lssndrbarbieri@gmail.com</email>
+		<name>Alessandro Barbieri</name>
+	</maintainer>
+	<longdescription lang="en">
+Pifpaf is a suite of fixtures and a command-line tool that allows to start and stop daemons for a quick throw-away usage. This is typically useful when needing these daemons to run integration testing. It originaly evolved from its precussor overtest.
+	</longdescription>
+	<upstream>
+		<remote-id type="github">jd/pifpaf</remote-id>
+		<remote-id type="pypi">pifpaf</remote-id>
+	</upstream>
+</pkgmetadata>

dev-util/pifpaf/pifpaf-3.1.5-r1.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 pypi
+
+DESCRIPTION="Suite of tools and fixtures to manage daemons for testing"
+HOMEPAGE="
+	https://pypi.org/project/pifpaf/
+	https://github.com/jd/pifpaf
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# dev-python/pbr: for pbr.version
+# dev-python/setuptools: for pkg_resources and distutils
+RDEPEND="
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/daiquiri[${PYTHON_USEDEP}]
+	dev-python/fixtures[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/pbr[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/xattr[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/pbr[${PYTHON_USEDEP}]
+	test? (
+		app-admin/consul
+		app-admin/vault
+		dev-db/postgresql[server]
+		dev-db/redis
+		dev-python/httpbin[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+		net-misc/kafka-bin
+		net-misc/memcached
+		sys-cluster/ceph
+		virtual/mysql[server]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Need updates to new CLIs and APIs
+	pifpaf/tests/test_drivers.py::TestDrivers::test_etcd
+	pifpaf/tests/test_drivers.py::TestDrivers::test_influxdb
+	pifpaf/tests/test_drivers.py::TestDrivers::test_mongodb
+	pifpaf/tests/test_drivers.py::TestDrivers::test_rabbitmq
+	pifpaf/tests/test_drivers.py::TestDrivers::test_rabbitmq_cluster
+	pifpaf/tests/test_drivers.py::TestDrivers::test_redis_sentinel
+)
+
+distutils_enable_tests pytest