diff --git a/dev-libs/gmobile/Manifest b/dev-libs/gmobile/Manifest
index b1e9d98e42..01d0c89c12 100644
--- a/dev-libs/gmobile/Manifest
+++ b/dev-libs/gmobile/Manifest
@@ -1,2 +1,4 @@
 DIST gmobile-0.1.0.tar.xz 45044 BLAKE2B 90d9efaf4383392fc55c15540ae7b600cea486750885d22df467fb20ade748d28784856301fbdd614a9148dbc40f015a8f8a8369dff310f54e95e1468b8c966d SHA512 eb17d0b39d5dbe197a2502fe974af37076317094c4759bbc4924d951fdb1bdb1fe8f13a85419dad756954c165bbd6dfca4ce555f6e3f5a3def4bac8bc913ab1a
 DIST gmobile-0.1.0.tar.xz.asc 833 BLAKE2B 30c6a97e78cb03beda468e1759d73d55892f61785adcde390195b0089df039a2c50882e0f22d2db925a324af0869d659d6c9dc71f405bfd608a07521481e261b SHA512 a90ff042dcd6e26508e9927a92c3ab537ca9556a758e2064d0a480c11b83c1355f6422f9e2ee0a51dc4e28355ef9b626b0c0388ed59363c42581037d5b781080
+DIST gmobile-0.2.1.tar.xz 54500 BLAKE2B 4daf129db96db9251320bf31d2a9d4951cd55b4622a69d45fbaa0b716d967aada4cc72a1594a96ed48dd5f822f4de032b8957f38f57d31db7602ef2d5af4d93e SHA512 f572900d177f12554357fe467aca98a61ea9b95f0ceffa64f877d78d627d32c7dbc4ca2665c2602ca16097d6aab53fddfc413055f4810e10d55c331c5ebf147c
+DIST gmobile-0.2.1.tar.xz.asc 833 BLAKE2B 96736ec7924ac279da7b42cb37a53005bb1af4aa18786445e04bacac49c1a79f56b8e7184c69eb14bbc982de6bead322f4748cc11fa0bc91b53f642b9530dd6b SHA512 89fd0d2033a3eff1b599df6eff495fb91315d7ea11c4d311bcdc4aab43003d7ad1ab83e4ae41f4cdaf600f9110f31f86cfedcaf294a9622bdb2dd728d7d8d1cf
diff --git a/dev-libs/gmobile/gmobile-0.2.1.ebuild b/dev-libs/gmobile/gmobile-0.2.1.ebuild
new file mode 100644
index 0000000000..07f00b670f
--- /dev/null
+++ b/dev-libs/gmobile/gmobile-0.2.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+VALA_USE_DEPEND="vapigen"
+
+inherit meson udev verify-sig
+
+DESCRIPTION="Mobile related helpers for glib based projects"
+HOMEPAGE="https://gitlab.gnome.org/World/Phosh/gmobile/"
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
+	verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="gtk-doc +introspection man test udev"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/glib-2.66:2
+	>=dev-libs/json-glib-1.6.2
+	introspection? ( dev-libs/gobject-introspection )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	gtk-doc? ( >=dev-util/gi-docgen-2021.1 )
+	man? ( dev-python/docutils )
+	verify-sig? ( sec-keys/openpgp-keys-phosh )
+"
+IDEPEND="udev? ( virtual/udev )"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
+
+src_configure() {
+	local emesonargs=(
+		-Dexamples=false
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		$(meson_use man)
+		$(meson_use test tests)
+		$(meson_use udev hwdb)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	# https://bugs.gentoo.org/930407
+	find "${ED}"/usr/$(get_libdir) -name "*.a" -delete || die
+
+	if use gtk-doc; then
+		local gtkdocdir="${ED}/usr/share/gtk-doc/html/"
+		mkdir -p "${gtkdocdir}" || die
+		mv "${ED}"/usr/share/doc/${PN}-${SLOT} "${gtkdocdir}" || die
+	fi
+}
+
+pkg_postinst() {
+	use udev || return 0
+
+	udev_reload
+}
+
+pkg_postrm() {
+	use udev || return 0
+
+	udev_reload
+}