From 6d0c9cb9b6db07dde861b7a37e2811b7c07e5ab4 Mon Sep 17 00:00:00 2001
From: Paul Zander <negril.nx+gentoo@gmail.com>
Date: Sun, 7 Sep 2025 09:35:59 +0200
Subject: [PATCH] x11-drivers/evdi: add 1.14.11

Signed-off-by: Paul Zander <negril.nx+gentoo@gmail.com>
---
 x11-drivers/evdi/Manifest            |  1 +
 x11-drivers/evdi/evdi-1.14.11.ebuild | 83 ++++++++++++++++++++++++++++
 2 files changed, 84 insertions(+)
 create mode 100644 x11-drivers/evdi/evdi-1.14.11.ebuild

diff --git a/x11-drivers/evdi/Manifest b/x11-drivers/evdi/Manifest
index 5ee303c9b2..97dd02e737 100644
--- a/x11-drivers/evdi/Manifest
+++ b/x11-drivers/evdi/Manifest
@@ -1 +1,2 @@
 DIST evdi-1.14.10.tar.gz 97166 BLAKE2B 67e489a3287d773262997cb16337293979fbbfe01b7e32de0dbdf1ab95bcfc25e08707d5fdb44a735a561579b2888d7578761051e78ec34dc76429eb261519ff SHA512 3937af9a2cc377f505c45de4ad0c28c778ef91ee7157341dfe411c8c1dde6c665cede26963678b7492688338059dd57f7fe296666e439240eb0f4d478bafbc28
+DIST evdi-1.14.11.tar.gz 97424 BLAKE2B ffdb7071cc69b9788b1980273428122954dcff276bd13f693598d54a15ea796390e3b57827f8003be0a5c1157aab0fdf75a71f28b0cb7bc46fd199715b8997b7 SHA512 30d21a1b5ba2ecad827a98d7e826da8e3320919baf51b92410048d9d0fdc8f236c24fa20fafd18d946bb72c0b809c98ba1fd7fa3da5058c1b35959ecb04b5ea6
diff --git a/x11-drivers/evdi/evdi-1.14.11.ebuild b/x11-drivers/evdi/evdi-1.14.11.ebuild
new file mode 100644
index 0000000000..f4105664f4
--- /dev/null
+++ b/x11-drivers/evdi/evdi-1.14.11.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+inherit linux-mod-r1 python-single-r1 flag-o-matic
+
+DESCRIPTION="Extensible Virtual Display Interface"
+HOMEPAGE="https://github.com/DisplayLink/evdi"
+SRC_URI="https://github.com/DisplayLink/evdi/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0/$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+IUSE="python test"
+
+RDEPEND="${PYTHON_DEPS}
+	python? (
+		$(python_gen_cond_dep '
+			dev-python/pybind11[${PYTHON_USEDEP}]
+			test? (
+				dev-python/pytest-mock[${PYTHON_USEDEP}]
+			)
+		')
+	)
+"
+
+DEPEND="${RDEPEND}
+	x11-libs/libdrm
+	sys-kernel/linux-headers
+"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RESTRICT="!test? ( test )"
+
+# module/Kconfig
+CONFIG_CHECK="~FB_VIRTUAL ~I2C ~DRM ~USB_SUPPORT ~USB_ARCH_HAS_HCD MODULES"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.14.4-format-truncation.patch"
+)
+
+pkg_setup() {
+	linux-mod-r1_pkg_setup
+	use python && python-single-r1_pkg_setup
+}
+
+src_compile() {
+	filter-lto
+
+	local modlist=(
+		"evdi=video:module"
+	)
+	local modargs=(
+		CONFIG_DRM_EVDI="m" # https://github.com/DisplayLink/evdi/issues/476
+		KVER="${KV_FULL}"
+		KDIR="${KV_OUT_DIR}"
+	)
+	linux-mod-r1_src_compile
+
+	emake -C library
+
+	use python && emake -C pyevdi
+}
+
+src_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+
+	use python && emake -C pyevdi tests
+}
+
+src_install() {
+	linux-mod-r1_src_install
+
+	local -x DESTDIR="${ED}" PREFIX="${EPREFIX}"
+
+	LIBDIR="/usr/$(get_libdir)" emake -C library install
+
+	use python && emake -C pyevdi install
+}