net-im/mautrix-telegram: add 0.15.1

Signed-off-by: Julien Roy <julien@jroy.ca>

net-im/mautrix-telegram/Manifest

@@ -1,2 +1,3 @@
 DIST mautrix-telegram-0.14.1.gh.tar.gz 811724 BLAKE2B 92cc600c5838c9bf65e9aa76a499b63d9474087d998d764f4e0f146cbcc7f9e7d10e7c0f3a7a6d31c3c9d9ff5e75070ea0fe35526455a66a342d96d2fb47cb4b SHA512 7615dc811558119f0e54184af057fba399824b5d753b9dd45ea25c943d710fa66b0dd5bbcbf9162840ee53f771cbf07f3017d563ecbf34b911ff3e28398e54b3
 DIST mautrix-telegram-0.14.2.gh.tar.gz 813171 BLAKE2B 286015b2854b5c2649f27e32e9d87faf852b42227864415692b78a306c85691786e6992d6137ccc30b3c947294b3c417c455c1b433384ddcbeab6aaf10586898 SHA512 0745beb448afaefcd7bafa6425e5fe8469729d208cb8eb6c248c35bc83ce75c6c916434b7d1e6671a37215cab041eaa61c5a6b0b5ee367f9ac5f83b1cfc651a9
+DIST mautrix-telegram-0.15.1.tar.gz 253573 BLAKE2B f27e5d97e9f225d8464e2002c02895072c0ddff7cad388bde08716a9337c3fd72291d0e087677fc69f9b298f297418f931e12e536695c30300b1526f1960a579 SHA512 f9a8898e8bfcc79b4e6ddc0cc9473e195f9c772ccc621275c688927e35a7f0801edea3a053b462c155757e4231465670ab5dc305d7fb39438590d953eb6b163b

net-im/mautrix-telegram/mautrix-telegram-0.15.1.ebuild

@@ -0,0 +1,82 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYPI_NO_NORMALIZE=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 optfeature pypi systemd
+
+DESCRIPTION="A Matrix-Telegram Messenger puppeting bridge "
+HOMEPAGE="https://github.com/mautrix/telegram/"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	acct-user/${PN}
+	app-arch/brotli[python]
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/aiodns[${PYTHON_USEDEP}]
+	dev-python/aiosqlite[${PYTHON_USEDEP}]
+	dev-python/asyncpg[${PYTHON_USEDEP}]
+	dev-python/commonmark[${PYTHON_USEDEP}]
+	dev-python/cryptg[${PYTHON_USEDEP}]
+	dev-python/mako[${PYTHON_USEDEP}]
+	dev-python/mautrix[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/python-olm[${PYTHON_USEDEP}]
+	dev-python/phonenumbers[${PYTHON_USEDEP}]
+	dev-python/pycryptodome[${PYTHON_USEDEP}]
+	dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/qrcode[${PYTHON_USEDEP}]
+	dev-python/python-socks[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	>=dev-python/tulir-telethon-1.34.0_alpha2[${PYTHON_USEDEP}]
+	dev-python/unpaddedbase64[${PYTHON_USEDEP}]
+	dev-python/yarl[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+src_install() {
+	distutils-r1_src_install
+
+	keepdir /var/log/mautrix
+	fowners root:mautrix /var/log/mautrix
+	fperms 770 /var/log/mautrix
+	sed -i -e "s/\.\/${PN}.log/\/var\/log\/mautrix\/${PN}.log/" "${ED}/usr/example-config.yaml" || die
+
+	insinto "/etc/mautrix"
+	newins "${ED}/usr/example-config.yaml" "${PN/-/_}.yaml"
+	rm "${ED}/usr/example-config.yaml" || die
+
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}.service"
+
+	fowners -R root:mautrix /etc/mautrix
+	fperms -R 770 /etc/mautrix
+}
+
+pkg_postinst() {
+	optfeature "Prometheus statistics" dev-python/prometheus_client
+	optfeature "Sqlite backend" dev-python/aiosqlite
+
+	einfo
+	elog ""
+	elog "Before you can use ${PN}, you must configure it correctly"
+	elog "The configuration file is located at \"/etc/mautrix/${PN/-/_}.yaml\""
+	elog "When done, run the following command: emerge --config ${CATEGORY}/${PN}"
+	elog "Then, you must register the bridge with your homeserver"
+	elog "Refer your homeserver's documentation for instructions"
+	elog "The registration file is located at /var/lib/${PN/-/\/}/registration.yaml"
+	elog "Finally, you may start the ${PN} daemon"
+	einfo
+}
+
+pkg_config() {
+	su - "${PN}" -s /bin/sh -c \
+	   "/usr/bin/python -m ${PN/-/_} -c /etc/mautrix/${PN/-/_}.yaml -g -r /var/lib/${PN/-/\/}/registration.yaml"
+}