dev-util/kubetail: add 0.17.0

Signed-off-by: Andres Morey <andres@kubetail.com>
Part-of: https://github.com/gentoo/guru/pull/469
Closes: https://github.com/gentoo/guru/pull/469
Signed-off-by: David Roman <stkw0@disroot.org>

dev-util/kubetail/Manifest

@@ -1,2 +1,3 @@
 DIST kubetail-0.15.0-vendored.tar.gz 20905816 BLAKE2B 9b28eb2c6414d2c273bbc3587952ea86f4bb21cc0e4aa32b61b8e1b0190d6885cf6f4195da91852b8f684c1ad935bbdbc629b386d3ce9fc19c6220cbb4a158cb SHA512 fc38896e9a3f9300317255566fc3a9ed27127e2e0d41380de29eb2175a57d69e89566e0ea7626fcc85ae364323ac0a0ed94f7b1e11a4b10c4aaedc3dcff8cfcc
 DIST kubetail-0.16.0-vendored.tar.gz 20815085 BLAKE2B f28ff9acac902b04ac7bf3ff247fbf779d9007f2bb9ad3043a5b0d3ecfa77723e86673c328bffc4a431eccce57a5eb7d7a92b721d88eff6326a5ad8db65bb656 SHA512 0100d92eb3ca5613fd557cc979d1c56b8351913d3635d601c7ccd13aaba6ea8b1e1ffe1ea54f0668147db536b9f0f4ea7b3103b3d3a2fc2710af073d0021ba7e
+DIST kubetail-0.17.0-vendored.tar.gz 21084536 BLAKE2B a0b347c497d21cd575ada895e3f9589a56e6fd6f6d9daa7138bc50994d13c898bd7a1f03322d263714e4c1f94bcb50f478a5aad5e2fa515fc359ef7c5e83d539 SHA512 44a5f87d60f81fd862d80002bcee9f20d2ad93d61b6d00afc24701d13835c9f8e4712032e86079c01c80441d9e19ad02f2e5e3474be075e020a88b1f58a9371c

dev-util/kubetail/kubetail-0.17.0.ebuild

@@ -0,0 +1,45 @@
+# Copyright 2021-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit go-module shell-completion
+
+DESCRIPTION="Real-time logging dashboard for Kubernetes"
+
+HOMEPAGE="https://github.com/kubetail-org/kubetail"
+
+SRC_URI="https://github.com/kubetail-org/kubetail/releases/download/cli%2Fv${PV}/kubetail-${PV}-vendored.tar.gz"
+
+S="${WORKDIR}/kubetail-${PV}/modules/cli"
+
+LICENSE="Apache-2.0"
+
+SLOT="0"
+
+KEYWORDS="~amd64 ~arm64"
+
+BDEPEND=">=dev-lang/go-1.25.0"
+
+src_compile() {
+	(
+		GOWORK=off \
+		ego build \
+			-mod=vendor \
+			-ldflags "-X github.com/kubetail-org/kubetail/modules/cli/cmd.version=${PV}" \
+			-o "${PN}" \
+			.
+	)
+
+	"./${PN}" completion bash > "${PN}.bash" || die
+	"./${PN}" completion zsh > "${PN}.zsh" || die
+	"./${PN}" completion fish > "${PN}.fish" || die
+}
+
+src_install() {
+	dobin "${PN}"
+
+	newbashcomp "${PN}.bash" "${PN}"
+	newzshcomp "${PN}.zsh" "_${PN}"
+	dofishcomp "${PN}.fish"
+}