dev-python/mastodon-py: add 1.8.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-python/mastodon-py/Manifest

@@ -1 +1,2 @@
 DIST Mastodon.py-1.7.0.tar.gz 8633772 BLAKE2B e27827cf7b5a010616524355c51771709591ee498b398cb009fe73697a96a313880e9f81e138c48c9f144fe9b35222b6852d84a2b4648803604b0a3a9ed190c3 SHA512 faa056fc800104a732524126458baec68ef838fe36fb7df5721262f6faf61e0f5591026efb1a19612ceeaa785eb81b4aab55728479bf216f6d2b9afcfedcdd18
+DIST Mastodon.py-1.8.0.tar.gz 8659035 BLAKE2B 46c07fc3e3cf289f8a161975b1f3f36a88882c3299e79b331f3c659c18c5cafbc7144be57bf580212152a345ab4c4e73a08ea4d6052953fae6664eabd6360c3f SHA512 497cdb42adeceeea6f65210daf94eff0c6ce26b286fabc13976c8276649b6b6f51f47b4e99733133c60dc373fcbb0b0760a20ff526d8435391c43e8f06666696

dev-python/mastodon-py/mastodon-py-1.8.0.ebuild

@@ -0,0 +1,55 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+inherit distutils-r1 optfeature
+
+MY_PN="Mastodon.py"
+MY_P="${MY_PN}-${PV}"
+DESCRIPTION="Python wrapper for the Mastodon API"
+HOMEPAGE="
+	https://pypi.org/project/Mastodon.py/
+	https://github.com/halcy/Mastodon.py
+"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/blurhash[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/http_ece[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-vcr[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/vcrpy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs
+
+src_prepare() {
+	distutils-r1_src_prepare
+	rm setup.cfg || die
+}
+
+pkg_postinst() {
+	optfeature "webpush support" "dev-python/cryptography dev-python/http_ece"
+}