media-gfx/bambustudio-bin: add 02.08.02.60

Signed-off-by: Huang Rui <vowstar@gmail.com>

media-gfx/bambustudio-bin/Manifest

@@ -1,2 +1,3 @@
 DIST bambustudio-bin-02.07.01.57.AppImage 227875320 BLAKE2B 4e962377e6251b4056b16dce0ba8d405a69492aa1e5243127d6cfb09b9d7290ac2270b71f118d443239fb0bdd049faf8ae2a7c72477f41c50f9df55b989ac680 SHA512 ce1e547789985afc6b914cd02972f1bc53829adbdc37481e1cb26981d8e340a0fbf3a12359df594d70fbade014510539329af1f2163c3c0cfe40146e519fdf3f
 DIST bambustudio-bin-02.07.01.62.AppImage 227047928 BLAKE2B b9675554cf129cf2380633de54a063571251cdb33033504a7397f323096a45123182d0d1fde0c7818a4b6f37984daa87a69cfffe95b43d9dc8d7c1e18e43e836 SHA512 995ecd9a2a2d9a45eb8ae2c2c89eb3b42b167d7bd5ad5c932ad2e79391b3ec39391b728b7c183786b564772d6a25e5e251cc7ad392dbc085d3e7f149fd504f1e
+DIST bambustudio-bin-02.08.02.60.AppImage 230021624 BLAKE2B fcb70f5374ffd95b67e7af00bb91b6d3ccda6bc016eac2bd5e4ca3984a66eab3773761ceff6eabab746eb5ea0b330948ca3d8cd1212b93dfa2d03c8db4552a0e SHA512 b6db2e76b7d69bbbcc91056cb0622a5510ae4f88bc4ef5238d55e2c65b35f660c2ad1c7de87daaf93f7ef8352e7136d9f9f514f57bd0b315a1f37f601ccd0a68

media-gfx/bambustudio-bin/bambustudio-bin-02.08.02.60.ebuild

@@ -0,0 +1,91 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="BambuStudio"
+WX_GTK_VER="3.2-gtk3"
+
+inherit desktop wrapper xdg
+
+DESCRIPTION="Bambu Studio is a cutting-edge, feature-rich slicing software"
+HOMEPAGE="https://bambulab.com"
+
+SRC_URI="
+	amd64? (
+		https://github.com/bambulab/${MY_PN}/releases/download/v${PV}/BambuStudio_ubuntu24.04-v02.08.02.60-20260814171356.AppImage
+		-> ${P}.AppImage
+	)
+"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/wayland
+	media-gfx/openvdb
+	media-libs/fontconfig
+	media-libs/glew:0
+	>=media-libs/glm-0.9.9.1
+	media-libs/gst-plugins-base
+	media-libs/gstreamer
+	media-libs/libglvnd
+	media-libs/mesa
+	net-libs/libsoup:2.4
+	net-libs/webkit-gtk:4.1
+	>=sci-libs/opencascade-7.3.0:0
+	sys-apps/dbus
+	virtual/glu
+	virtual/zlib
+	>=x11-libs/cairo-1.8.8:0
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libxkbcommon
+	x11-libs/pango
+	>=x11-libs/pixman-0.30
+	x11-libs/wxGTK:${WX_GTK_VER}[X,opengl]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/patchelf
+"
+
+QA_PREBUILT="*"
+RESTRICT="strip test"
+
+src_unpack() {
+	mkdir "${S}" || die
+	cp "${DISTDIR}/${P}.AppImage" "${S}"/ || die
+	pushd "${S}" || die
+	chmod +x "${S}/${P}.AppImage" || die
+	"${S}/${P}.AppImage" --appimage-extract || die
+	rm "${S}/${P}.AppImage" || die
+	popd || die
+}
+
+src_install() {
+	# Set RUNPATH so the bundled libraries in /opt/${PN}/bin/ are found.
+	# The ubuntu-24.04 AppImage links directly against webkit-gtk:4.1,
+	# so no soname replacement is needed anymore.
+	patchelf --set-rpath '$ORIGIN' \
+		"${S}"/squashfs-root/bin/bambu-studio || die
+
+	# Ubuntu ships bzip2 with SONAME libbz2.so.1.0; Gentoo uses libbz2.so.1.
+	# Rewrite NEEDED entries so qa-unresolved-soname-deps is satisfied and the
+	# binary stays linkable after Gentoo drops the libbz2.so.1.0 compat symlink.
+	local f
+	while IFS= read -r -d '' f; do
+		[[ -L ${f} ]] && continue
+		patchelf --print-needed "${f}" 2>/dev/null | grep -qxF 'libbz2.so.1.0' || continue
+		patchelf --replace-needed libbz2.so.1.0 libbz2.so.1 "${f}" || die
+	done < <(find "${S}"/squashfs-root -type f -print0)
+
+	insinto /opt/"${PN}"
+	doins -r "${S}"/squashfs-root/*
+	fperms +x "/opt/${PN}/AppRun" "/opt/${PN}/bin/bambu-studio"
+	doicon -s 192 "${S}"/squashfs-root/BambuStudio.png
+	domenu "${FILESDIR}/bambu-studio.desktop"
+	make_wrapper bambu-studio "/opt/${PN}/AppRun"
+}