diff --git a/dev-util/rpmlint/Manifest b/dev-util/rpmlint/Manifest
new file mode 100644
index 0000000000..5c9b4c8808
--- /dev/null
+++ b/dev-util/rpmlint/Manifest
@@ -0,0 +1 @@
+DIST rpmlint-1.11_p20210515.tar.gz 5670517 BLAKE2B b85727f45cf56a89d0b7a1394b72f627cde6704236851e548712c19389baced8dc86995fad0d5ee274e79e10cece553e4b2870b012d8063eef93d56c03f5ee5c SHA512 c8b40b93cfeb16b96588536948c84b0bbfed18b9e63668b68d8b7574e7bc90c5a15a7efc2b612ea4d4db470b156f5e29abee7acb69f3edb86d20482e499b0140
diff --git a/dev-util/rpmlint/files/no-coverage.patch b/dev-util/rpmlint/files/no-coverage.patch
new file mode 100644
index 0000000000..86edc54ecd
--- /dev/null
+++ b/dev-util/rpmlint/files/no-coverage.patch
@@ -0,0 +1,8 @@
+--- a/setup.cfg
++++ b/setup.cfg
+@@ -10,4 +10,4 @@
+ application-import-names = Testing
+ 
+ [tool:pytest]
+-addopts = -vv --cov=rpmlint -n auto --flake8
++addopts = -vv
diff --git a/dev-util/rpmlint/metadata.xml b/dev-util/rpmlint/metadata.xml
new file mode 100644
index 0000000000..3bf9e7edc9
--- /dev/null
+++ b/dev-util/rpmlint/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<description>comaintainers welcome</description>
+		<email>lssndrbarbieri@gmail.com</email>
+		<name>Alessandro Barbieri</name>
+	</maintainer>
+	<longdescription lang="en">
+		rpmlint is a tool for checking common errors in rpm packages. It can be
+		used to test individual packages and spec files before uploading or to
+		check an entire distribution. By default all applicable checks are
+		processed but specific checks can be performed by using command line
+		parameters.
+	</longdescription>
+</pkgmetadata>
diff --git a/dev-util/rpmlint/rpmlint-1.11_p20210515.ebuild b/dev-util/rpmlint/rpmlint-1.11_p20210515.ebuild
new file mode 100644
index 0000000000..a8543c0f3b
--- /dev/null
+++ b/dev-util/rpmlint/rpmlint-1.11_p20210515.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+COMMIT="af4cbdcc93267c065fbb7c7248d203977343523f"
+DISTUTILS_SINGLE_IMPL=1
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Tool for checking common errors in RPM packages"
+HOMEPAGE="https://github.com/rpm-software-management/rpmlint"
+SRC_URI="https://github.com/rpm-software-management/rpmlint/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${COMMIT}"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	app-arch/bzip2
+	app-arch/cpio
+	app-arch/gzip
+	app-arch/xz-utils
+	app-arch/zstd
+	sys-devel/binutils:*
+
+	$(python_gen_cond_dep '
+		app-arch/rpm[python,${PYTHON_SINGLE_USEDEP}]
+		dev-python/pybeam[${PYTHON_USEDEP}]
+		dev-python/pyxdg[${PYTHON_USEDEP}]
+		dev-python/toml[${PYTHON_USEDEP}]
+		dev-python/zstd[${PYTHON_USEDEP}]
+	')
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		app-shells/dash
+		dev-libs/appstream-glib
+		dev-util/desktop-file-utils
+		dev-util/devscripts
+		|| (
+			( app-text/hunspell[l10n_cs,l10n_en] app-text/enchant[hunspell] )
+			( app-text/aspell[l10n_cs,l10n_en] app-text/enchant[aspell] )
+		)
+
+		$(python_gen_cond_dep '
+			dev-python/pyenchant[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			dev-python/python-magic[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+PATCHES=( "${FILESDIR}/no-coverage.patch" )
+
+distutils_enable_tests pytest
+
+python_test() {
+	pytest -vv \
+			--deselect test/test_speccheck.py::test_check_invalid_url[spec/SpecCheck2] \
+			--deselect test/test_lint.py::test_run_installed_and_no_files \
+			--deselect test/test_lint.py::test_run_installed[packages0] \
+			--deselect test/test_ldd_parser.py::test_dependencies \
+	|| die
+}