games-util/minigalaxy: add 1.4.0

Signed-off-by: Lucio Sauer <watermanpaint@posteo.net>

games-util/minigalaxy/Manifest

@@ -1 +1,2 @@
 DIST minigalaxy-1.3.2.tar.gz 454224 BLAKE2B ef34dbcccec29e802332f33226877b8db50d7d1a676aad0377a570604442cf3e37d1143ad2da6bdd91010f2583c2fad8888ba7f96561b000252cca6c36b1c43d SHA512 61a3046ff2baf075f115110b6e516c399eed6772697f5715ee8fbc032fb8ddbec7b7fddbbbe4b39cfb212acbcf4e7431dd86eec5871bf957b467f65cd26fb4ef
+DIST minigalaxy-1.4.0.tar.gz 502559 BLAKE2B 1e56c90a89c305ae33929d6b71e40e6186ef2ac95e7010e4aa641d97f894e066ef10766a05ea2c4a7e63c41a7b0428d80699cb900f28f091b71ca2b3a7041346 SHA512 2650e6b5662b3104129f45c6415a32e9369f31b1b3bc6d0ace1441dc1e88e8dce6f4d1e68e9f8b5048922e517c964b5a9612dca309b4e46e12e6816403ddc9c4

games-util/minigalaxy/minigalaxy-1.4.0.ebuild

@@ -0,0 +1,99 @@
+# Copyright 2020-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit desktop optfeature python-single-r1 xdg
+
+DESCRIPTION="A simple GOG client for Linux"
+HOMEPAGE="https://github.com/sharkwouter/minigalaxy"
+SRC_URI="https://github.com/sharkwouter/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+# x11-libs/gdk-pixbuf[jpeg] dependency for thumbnails in library entries
+# x11-libs/libnotify dependency in minigalaxy/ui/gtk.py
+RDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		>=dev-python/requests-2.0.0[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	app-arch/unzip
+	>=net-libs/webkit-gtk-2.6:4.1[introspection]
+	>=x11-libs/gtk+-3[introspection]
+	x11-libs/gdk-pixbuf[introspection,jpeg]
+	x11-libs/libnotify[introspection]
+	x11-misc/xdg-utils
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	sys-apps/help2man
+	sys-devel/gettext
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep '
+			dev-python/simplejson[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+src_prepare() {
+	sed -e "s:os.path.dirname(sys.argv\[0\]):'${EPREFIX}/usr/share/':" \
+		-e "s:minigalaxy/translations:locale:" \
+		-i minigalaxy/paths.py || die
+	default
+}
+
+src_compile() {
+	help2man -N -s 6 -n "a simple GTK-based GOG Linux client" bin/minigalaxy > minigalaxy.6 || die
+	lo_files=( data/po/*.po )
+	local lo
+	for lo in "${lo_files[@]%.po}"; do
+		msgfmt "${lo}.po" -o "${lo}.mo" || die
+	done
+}
+
+src_test() {
+	eunittest tests
+}
+
+src_install() {
+	insinto /usr/share/minigalaxy
+	doins -r data/images data/ui data/style.css
+	insinto /usr/share/metainfo
+	doins data/io.github.sharkwouter.Minigalaxy.metainfo.xml
+
+	doman minigalaxy.6
+	domo "${lo_files[@]/%.po/.mo}"
+	unset lo_files
+
+	local x
+	for x in 128 192; do
+		doicon -s ${x} data/icons/${x}x${x}/io.github.sharkwouter.Minigalaxy.png
+	done
+
+	domenu data/io.github.sharkwouter.Minigalaxy.desktop
+
+	dodoc README.md CHANGELOG.md
+
+	python_domodule minigalaxy
+	python_doscript bin/minigalaxy
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "choosing the language of Windows games before installation" app-arch/innoextract
+	optfeature "running games with system dosbox" games-emulation/dosbox
+	optfeature "running games with system scummvm" games-engines/scummvm
+	optfeature "running games with system wine" virtual/wine
+}