dev-python/readability-lxml: add 0.8.1

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-python/readability-lxml/readability-lxml-0.8.1.ebuild

@@ -0,0 +1,49 @@
+# Copyright 2019-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+MY_PN="python-readability"
+DESCRIPTION="fast html to text parser (article readability tool)"
+HOMEPAGE="
+	https://pypi.org/project/readability-lxml/
+	https://github.com/buriy/python-readability
+"
+SRC_URI="https://github.com/buriy/${MY_PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/cssselect[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	|| ( ( $(python_gen_cond_dep \
+			'dev-python/cchardet[${PYTHON_USEDEP}]' python3_{8..10}) )
+		dev-python/chardet[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep \
+			'dev-python/timeout-decorator[${PYTHON_USEDEP}]' python3_{8..11})
+	)
+"
+
+distutils_enable_tests unittest
+
+distutils_enable_sphinx doc/source \
+	dev-python/recommonmark \
+	dev-python/sphinx_rtd_theme
+
+python_test() {
+	[[ ${EPYTHON} == pypy3 ]] && \
+		return 0  # unsatisfied dep
+
+	distutils-r1_python_test
+}