media-gfx/bambustudio-bin: add 02.00.00.95

Signed-off-by: Huang Rui <vowstar@gmail.com>

media-gfx/bambustudio-bin/Manifest

@@ -1 +1,2 @@
 DIST bambustudio-bin-01.10.02.76.AppImage 114255040 BLAKE2B 0f1488043e5e1a9202617a5ed047228433cfbeae86b842a8f9df6fba826de854512ca64b3a2db2aedba5ea303533cb10c23cb544058d0ac954f0d4454d6df2e5 SHA512 ccbdc3659f56bc80c24f8e29a99a39dbabd1f59a819518f563d63833b8d5571404e304cf0ae650ffdd815589e13d12ed14ebe7ce62d0d72538bccf8397ea3004
+DIST bambustudio-bin-02.00.00.95.AppImage 127939776 BLAKE2B 3207f74f2dc8b7eeae10575bae05fc35e8458983fa0c9c075d1bc7737fefa61e10fe6e3e7d6863299f58d3dd3637350f1a70a280a1996e17ed16028141017a3b SHA512 686efa598b6ce9a20897952dde3d78fd7504f11fe6e6e7ba23f3bed8957a0ce45c37e8cb177d23175e87f1153a6c1b5ba03cdb1d4d6ffd5a4af1f72fce290a4d

media-gfx/bambustudio-bin/bambustudio-bin-02.00.00.95.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="BambuStudio"
+WX_GTK_VER="3.0-gtk3"
+
+inherit desktop wrapper xdg
+
+DESCRIPTION="Bambu Studio is a cutting-edge, feature-rich slicing software"
+HOMEPAGE="https://bambulab.com"
+
+SRC_URI="
+	https://github.com/bambulab/${MY_PN}/releases/download/v${PV}/Bambu_Studio_linux_fedora-v${PV}.AppImage \
+	-> ${P}.AppImage
+"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+RDEPEND="
+	media-gfx/openvdb
+	media-libs/glew:0=
+	>=media-libs/glm-0.9.9.1
+	media-libs/gstreamer
+	media-libs/mesa[X(+),osmesa]
+	net-libs/libsoup:3.0=
+	net-libs/webkit-gtk:4.1/0
+	>=sci-libs/opencascade-7.3.0:0=
+	virtual/glu
+	>=x11-libs/cairo-1.8.8:=
+	x11-libs/libxkbcommon
+	>=x11-libs/pixman-0.30
+	x11-libs/wxGTK:${WX_GTK_VER}[X,opengl]
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/patchelf
+"
+
+QA_PREBUILT="*"
+RESTRICT="strip"
+
+src_unpack() {
+	mkdir "${S}" || die
+	cp "${DISTDIR}/${P}.AppImage" "${S}"/ || die
+	pushd "${S}" || die
+	chmod +x "${S}/${P}.AppImage" || die
+	"${S}/${P}.AppImage" --appimage-extract || die
+	rm "${S}/${P}.AppImage" || die
+	popd || die
+}
+
+src_install() {
+	rm -r squashfs-root/{*.{AppImage,desktop},.DirIcon,usr} || die
+	patchelf --replace-needed libwebkit2gtk-4.0.so.37 libwebkit2gtk-4.1.so.0 \
+		"${S}"/squashfs-root/bin/bambu-studio || die
+	patchelf --replace-needed libjavascriptcoregtk-4.0.so.18 libjavascriptcoregtk-4.1.so.0 \
+		"${S}"/squashfs-root/bin/bambu-studio || die
+	patchelf --remove-needed libsoup-2.4.so.1 \
+		"${S}"/squashfs-root/bin/bambu-studio || die
+	patchelf --set-rpath '$ORIGIN' \
+		"${S}"/squashfs-root/bin/bambu-studio || die
+	insinto /opt/"${PN}"
+	doins -r "${S}"/squashfs-root/*
+	fperms +x "/opt/${PN}/AppRun" "/opt/${PN}/bin/bambu-studio"
+	doicon -s 192 "${S}"/squashfs-root/BambuStudio.png
+	domenu "${FILESDIR}/bambu-studio.desktop"
+	make_wrapper bambu-studio "/opt/${PN}/AppRun"
+}