dev-python/django-widget-tweaks: new package, add 1.4.12

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-python/django-widget-tweaks/Manifest

@@ -0,0 +1 @@
+DIST django-widget-tweaks-1.4.12.gh.tar.gz 13174 BLAKE2B 2583d67aa5e8b96c5f53f363722ecdb2a0d312d66e61cea8e5702d1f5950509416a0b9a7f24936c6148ab5b7cf8a69d7e6843e7d0c5923aad93235b1785d129c SHA512 162f6a6c9ef55e08d49c26c6341766ad04f017157002b5ce8dad9da71eaf921df14b48b7097bcf67cb746861c52c963730b91fc1a736bff199112843bc7a9cca

dev-python/django-widget-tweaks/django-widget-tweaks-1.4.12.ebuild

@@ -0,0 +1,36 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+DESCRIPTION="Tweak the form field rendering in templates"
+HOMEPAGE="
+	https://pypi.org/project/django-widget-tweaks/
+	https://github.com/jazzband/django-widget-tweaks
+"
+SRC_URI="https://github.com/jazzband/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-python/django[${PYTHON_USEDEP}]"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? ( ${RDEPEND} )
+"
+
+DOCS=( {CHANGES,README}.rst {CODE_OF_CONDUCT,CONTRIBUTING}.md )
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	"${EPYTHON}" -m django test -v 2 --settings tests.settings ||
+		die "Tests failed with ${EPYTHON}"
+}

dev-python/django-widget-tweaks/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">django-widget-tweaks</remote-id>
+		<remote-id type="github">jazzband/django-widget-tweaks</remote-id>
+	</upstream>
+</pkgmetadata>