dev-python/databases: add 0.5.3

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-python/databases/Manifest

@@ -1 +1,2 @@
 DIST databases-0.4.3.tar.gz 26517 BLAKE2B 38b9f86e42740a723f4022b225913e0e7a2c635eb34793fcbf62efa0917ddb6b7ee3b59cce7f4c8503aef31befb0caea3fb3e655617606296cb8ae1bb4cebfc7 SHA512 aa49f1a33edd3bf9ae7aa203dcef4941d1a1766c930cbe34405caf3dca0801bbca494ec39357591b6339977b86294d32a031bf2020f206436e7d19edc6a8e158
+DIST databases-0.5.3.tar.gz 28342 BLAKE2B dcf8533a49b92a325bfda1440fd5bac3f9bd69751496c6fcdf72c422cc19c552a7458dc4ea0607a2a1ad9ade9afbb8cac00e178c29b6b11f7011bd4eae1f70a0 SHA512 bd0c4f1bf0f81e017ea55e41a6d4821ee17e0f995b600a50955fba68841443147dd234534b9c72d753b99785a5a08ac6e3d839894ec4760c602372cccbd4c1c0

dev-python/databases/databases-0.5.3.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="dev-python/mkdocs-material"
+
+inherit distutils-r1 docs optfeature
+
+DESCRIPTION="Async database support for Python."
+HOMEPAGE="
+	https://www.encode.io/databases/
+	https://github.com/encode/databases
+"
+SRC_URI="https://github.com/encode/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/sqlalchemy-1.4.0[${PYTHON_USEDEP}]
+	<dev-python/sqlalchemy-1.5.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="test? (
+	dev-python/aiopg[${PYTHON_USEDEP}]
+	dev-python/aiosqlite[${PYTHON_USEDEP}]
+	dev-python/async_timeout[${PYTHON_USEDEP}]
+	dev-python/asyncpg[${PYTHON_USEDEP}]
+	dev-python/psycopg[${PYTHON_USEDEP}]
+	dev-python/pymysql[${PYTHON_USEDEP}]
+	dev-python/starlette[${PYTHON_USEDEP}]
+)"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	tests/test_connection_options.py::test_mysql_pool_size
+	tests/test_connection_options.py::test_mysql_explicit_pool_size
+	tests/test_connection_options.py::test_mysql_ssl
+	tests/test_connection_options.py::test_mysql_explicit_ssl
+	tests/test_connection_options.py::test_mysql_pool_recycle
+	tests/test_databases.py
+	tests/test_integration.py::test_integration
+)
+
+python_prepare_all() {
+	# do not install LICENSE to /usr/
+	sed -i -e '/data_files/d' setup.py || die
+	# fix tests
+	sed -i -e '/databases.backends.mysql/d' tests/test_connection_options.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	TEST_DATABASE_URLS="" epytest
+}
+
+pkg_postinst() {
+	optfeature "postgresql support" dev-python/asyncpg dev-python/psycopg
+	optfeature "mysql support" dev-python/pymysql
+	optfeature "sqlite support" dev-python/aiosqlite
+	optfeature "postgresql+aiopg support" dev-python/aiopg
+}