dev-python/cyclopts: add 4.16.1

Signed-off-by: Florian Albrechtskirchinger <falbrechtskirchinger@gmail.com>

dev-python/cyclopts/Manifest

@@ -1 +1,2 @@
 DIST cyclopts-4.10.1.gh.tar.gz 2278757 BLAKE2B 04af4b675ede1313bcab80dd222c94c3bf9a0ca24cdb485e9320aa6074e399d8beb55b7ee9abd651140d52d10d3969606f861fcc15abd1ef7cfe7d28507ea4da SHA512 4674f79b1fa161f43468b4519a560241ecdc834c6bf26a60dad52755b22fa56e180db0fbcf03252872b61f70744da9754e0efa3fb0cff6a68201c468fabcd31e
+DIST cyclopts-4.16.1.gh.tar.gz 2336475 BLAKE2B ac5bc123d9b4286be687c86b77c8203a6933ff3ab3bd7575c06c4570cc44d485bdfc6adb59a6bda3ed5b98bc17677652bb0ac2eba8287d828e70a53bd02a1d3a SHA512 a4d1ca02ad59eee0b262500a587f3040482c7be1d17067a8b0e67a25744224d46a50b174ccb6c0dfabeb9bb94906eec25532bbba3b2b1136887290fc729b9986

dev-python/cyclopts/cyclopts-4.16.1.ebuild

@@ -0,0 +1,58 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Intuitive, easy CLIs based on type hints"
+HOMEPAGE="
+	https://github.com/BrianPugh/cyclopts
+	https://pypi.org/project/cyclopts/
+"
+SRC_URI="https://github.com/BrianPugh/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/attrs-23.1.0[${PYTHON_USEDEP}]
+	>=dev-python/docstring-parser-0.15[${PYTHON_USEDEP}]
+	>=dev-python/rich-13.6.0[${PYTHON_USEDEP}]
+	>=dev-python/rich-rst-1.3.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/pydantic-2.11.2[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-6.0.1[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		>=dev-python/trio-0.10.0[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=(
+	pytest-mock
+	syrupy
+)
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Requires dev-python/mkdocs
+	tests/test_docs_snapshots.py::TestMkDocsDirectiveSnapshots
+)
+EPYTEST_IGNORE=(
+	# Requires dev-python/mkdocs
+	tests/test_mkdocs_ext.py
+)
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+pkg_postinst() {
+	optfeature "Trio async backend" dev-python/trio
+	optfeature "reading YAML configurations" dev-python/pyyaml
+}