From 50aec9fc4b48d07797d471c7ec25b90913cd0805 Mon Sep 17 00:00:00 2001
From: Jonas Frei <freijon@pm.me>
Date: Tue, 14 Apr 2026 18:20:35 +0200
Subject: [PATCH] www-client/helium-bin: add 0.11.2.1

Signed-off-by: Jonas Frei <freijon@pm.me>
---
 www-client/helium-bin/Manifest                |   2 +
 .../helium-bin/helium-bin-0.11.2.1.ebuild     | 114 ++++++++++++++++++
 2 files changed, 116 insertions(+)
 create mode 100644 www-client/helium-bin/helium-bin-0.11.2.1.ebuild

diff --git a/www-client/helium-bin/Manifest b/www-client/helium-bin/Manifest
index ba867064b1..3ef832a413 100644
--- a/www-client/helium-bin/Manifest
+++ b/www-client/helium-bin/Manifest
@@ -4,3 +4,5 @@ DIST helium-bin-0.10.7.1-amd64.tar.xz 117196596 BLAKE2B e4152fe7eb673efab435d783
 DIST helium-bin-0.10.7.1-arm64.tar.xz 111771144 BLAKE2B 25be3e128131dd43e80b8ec745946459a39bc7a43315f8f16aa92c49645ba1e27edfbf9852f5f589456810b7a4ac6680730db241a7bd94d6bf2134c0c4a72ce1 SHA512 b2baf1fbe408cf51b8af8520440ce5b1bbb2243a18d4148c94b65cb1a2f509c14c2e9b16696640d124fdf8e61144ebce022de77203b7f2a7dab674699be70080
 DIST helium-bin-0.10.8.1-amd64.tar.xz 117355324 BLAKE2B 3c29ffdb66ac9f70f333acf0fbfe10fff986c0c88edea4a118973807010b595addffd0306e998d3723bce11671ed9ef625a1dbcf6b69b4821024022d68780f58 SHA512 2a7f7af2ef9a3fb8f0c1e72f2624b9a81d5420545c0f42b6c1994b1c9c16c40e7c5d31df910adeddd191113bd99b122dd0023c36a7548adeab077f442219e86e
 DIST helium-bin-0.10.8.1-arm64.tar.xz 111740300 BLAKE2B e985ebe7b07de3c4f55d7dc742e55b4c4a4571e9d3a29195cbd2fddd4b116bffc1aa7dd256cbe0ba000bf3dfc08e9b93c4563c0724d7abafed5b5c6b8528e0e8 SHA512 ad7493ad39daaf0c06cf40d3e7b94804648944b118c366988a151783d2854202778f1181b564ac4e8cf975d3fe1b90c532e6220a5bfb5f2c337e2267a3737040
+DIST helium-bin-0.11.2.1-amd64.tar.xz 113947632 BLAKE2B 7b248804572742bf681efe9f08e9705affc488854b41fa5cbbff96890114e38c49238bd091355c0401f50077d113ef2e197f3f3b7fbb1e12e6b3cf4f42ffa3ca SHA512 f14b91d3676bd5aeb2315b9413015ed4faa3c50e9799cef6c4240ed7ed4152cf371f735d7daba803312f704af606601a798c25b7e549beb038c0ae30682e17d7
+DIST helium-bin-0.11.2.1-arm64.tar.xz 108584880 BLAKE2B ae7802e99d963a26b71c2cb5eaf29cface437d46751e941f052223480ab0b2c04c02c0342321cf99bb993086b842ec754fd2e203a93e2461caa9d14ceea13887 SHA512 fadb451f9ef017edebc6876f2f140c8585dad88035ac906a9eb4290a8bce92d9d59f2f05b04b9859c749a68bb0ae8d6c9e2bfd4f81904feb8f3d0cd9c6722e0f
diff --git a/www-client/helium-bin/helium-bin-0.11.2.1.ebuild b/www-client/helium-bin/helium-bin-0.11.2.1.ebuild
new file mode 100644
index 0000000000..8a170a17cf
--- /dev/null
+++ b/www-client/helium-bin/helium-bin-0.11.2.1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2025-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="af am ar bg bn ca cs da de el en-GB en-US es-419 es
+	et fa fi fil fr gu he hi hr hu id it ja kn ko lt lv ml mr ms nb nl
+	pl pt-BR pt-PT ro ru sk sl sr sv sw ta te th tr uk ur vi zh-CN zh-TW"
+
+inherit chromium-2 desktop pax-utils xdg
+
+DESCRIPTION="Private, fast, and honest web browser based on Chromium"
+HOMEPAGE="https://helium.computer/"
+
+MY_PN="helium"
+MY_P="${MY_PN}-${PV}"
+
+if [[ ${ARCH} == amd64 ]] ; then
+	ARCH_TXT="x86_64"
+elif [[ ${ARCH} == arm64 ]] ; then
+	ARCH_TXT="${ARCH}"
+fi
+
+BASE_SRC_URI="https://github.com/imputnet/${MY_PN}-linux/releases/download/${PV}"
+SRC_URI="
+	amd64? ( ${BASE_SRC_URI}/${MY_P}-x86_64_linux.tar.xz -> ${P}-amd64.tar.xz )
+	arm64? ( ${BASE_SRC_URI}/${MY_P}-arm64_linux.tar.xz -> ${P}-arm64.tar.xz )
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-3 BSD"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~arm64"
+
+IUSE="qt6 selinux"
+
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-misc/ca-certificates
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	>=dev-libs/nss-3.26
+	media-fonts/liberation-fonts
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	sys-libs/libcap
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	|| (
+		x11-libs/gtk+:3[X]
+		gui-libs/gtk:4[X]
+	)
+	x11-libs/libdrm
+	>=x11-libs/libX11-1.5.0
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/pango
+	x11-misc/xdg-utils
+	qt6? ( dev-qt/qtbase:6[gui,widgets] )
+	selinux? ( sec-policy/selinux-chromium )
+"
+
+QA_PREBUILT="*"
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+# Skip unpack, we're doing it during install
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir "opt" || die
+	cd "${ED}/opt/" || die
+
+	# Not possible to unpack to target folder, so: unpack, then mv
+	unpack "${P}-${ARCH}.tar.xz"
+	mv ${MY_P}-${ARCH_TXT}_linux ${MY_PN} || die
+
+	cd "${MY_PN}" || die
+
+	pushd "locales" > /dev/null || die
+	# Remove empty .info files
+	rm *.info || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	rm "libqt5_shim.so" || die
+	if ! use qt6; then
+		rm "libqt6_shim.so" || die
+	fi
+
+	newicon -s 256 "product_logo_256.png" ${MY_PN}.png
+	domenu "${FILESDIR}/${MY_PN}.desktop"
+	dobin "${FILESDIR}/${MY_PN}"
+
+	pax-mark m "${MY_PN}"
+}