diff --git a/media-sound/yandex-music/Manifest b/media-sound/yandex-music/Manifest
index a4d9c93d18..8afb3983ce 100644
--- a/media-sound/yandex-music/Manifest
+++ b/media-sound/yandex-music/Manifest
@@ -2,3 +2,4 @@ DIST Yandex_Music_amd64_5.86.0.deb 92643586 BLAKE2B 9f6fe1aba2db6fc0ced4d749ca9d
 DIST Yandex_Music_amd64_5.88.0.deb 93678834 BLAKE2B 761d22f99b73d0d89483bee5c97f8973dfe0468a5d073fec6237ff5134b311d377689ad1614364d970b8f0a182a3c72eae17f5f33914e9de2e801e96345b6cc8 SHA512 26cb324646fa195094acd7b4578269d78561d87987f19349ba8ae05ad6675be23a3f8f9aca6ff76720b59eda59c6159b62b337d3f52b0bc755d50330cb1f0c92
 DIST Yandex_Music_amd64_5.90.0.deb 93754898 BLAKE2B 013327c8b6a539549d416e2dffda19cb2ea633098938e4727d49172d01e2228b357b684121bff155572f860f7879c7cdc1fbe99e742ae6b7b103a9c03c1a87e5 SHA512 a8992c32a2f67a2825661674365191e55aa9375c98c1bcd3b68c811db21ae22656ada1d48ea49c84bddcae49c1e0ea06f29c2398009dd9077fbe58dd74679d63
 DIST Yandex_Music_amd64_5.91.1.deb 93752812 BLAKE2B 133bfd55755a369885b4fbfdbbf2b61867178699833480f995f7f06310e64fa2e076608e35275a9584d055ba15a898c9e1b3f922d936b5192213ad1f6b720a0e SHA512 bb2da80f1f5b1b2726b40ed8663eacd923ee614a6f273de938fd2384bb8c21b20b5fed9e0f1ad53f6c81c6517f3481112a9e77f9b74001fe3f167034b3bfa6af
+DIST Yandex_Music_amd64_5.92.1.deb 93767688 BLAKE2B 2ac087ff2a3a4932d7d269839ebf58921baa9447c379acb244855634bf50ea8c6106ca9fcaddc0aa85c1f9da7436e2b885dec0781e99ebbf37ff3c9962a5cccd SHA512 b3c29b1bd03ffe6573ea898612e4333a5e2a5482d61983b685e6ca7d594cadb2ec91642f6372e3c9f8ae5a13d1675f877e294dab9e5b919111da6249ca901cac
diff --git a/media-sound/yandex-music/yandex-music-5.92.1.ebuild b/media-sound/yandex-music/yandex-music-5.92.1.ebuild
new file mode 100644
index 0000000000..32815afbbb
--- /dev/null
+++ b/media-sound/yandex-music/yandex-music-5.92.1.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="af am ar bg bn ca cs da de el en-GB en-US es-419 es et fa fi fil fr gu he hi hr hu id it ja kn ko \
+lt lv ml mr ms nb nl pl pt-BR pt-PT ro ru sk sl sr sv sw ta te th tr uk ur vi zh-CN zh-TW"
+inherit chromium-2 pax-utils wrapper unpacker xdg
+
+MY_PN="${PN/-/}"
+
+DESCRIPTION="Yandex Music streaming service"
+HOMEPAGE="https://music.yandex.ru/"
+SRC_URI="
+	amd64? ( https://music-desktop-application.s3.yandex.net/stable/Yandex_Music_amd64_${PV}.deb )
+"
+
+S="${WORKDIR}"
+
+LICENSE="Yandex-EULA"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-core
+	app-arch/bzip2
+	dev-libs/expat
+	dev-libs/fribidi
+	dev-libs/glib:2
+	dev-libs/gmp
+	dev-libs/libffi
+	dev-libs/libpcre2
+	dev-libs/libtasn1
+	dev-libs/libunistring
+	dev-libs/nettle
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/wayland
+	media-gfx/graphite2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/harfbuzz
+	media-libs/libepoxy
+	media-libs/libjpeg-turbo
+	media-libs/libpng
+	media-libs/mesa
+	net-dns/libidn2
+	net-libs/gnutls
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/systemd-utils
+	sys-apps/util-linux
+	sys-devel/gcc
+	sys-libs/glibc
+	sys-libs/libcap
+	virtual/zlib
+	x11-libs/cairo[X,glib]
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXdmcp
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/pango[X]
+	x11-libs/pixman
+"
+DEPEND="
+	>=dev-util/patchelf-0.9
+"
+
+QA_PREBUILT="*"
+QA_DESKTOP_FILE="usr/share/applications/yandex-music.*\\.desktop"
+YANDEX_HOME="opt/${PN}"
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	unpack_deb ${A}
+	mv -T "${S}/opt/Яндекс Музыка" "${S}/${YANDEX_HOME}" || die
+	mv -T "${S}/usr/share/doc/${MY_PN}" "${S}/usr/share/doc/${PF}" || die
+}
+
+src_prepare() {
+	default
+	sed -i -e "s|/opt/Яндекс Музыка/${MY_PN}|/opt/bin/${PN}|" -i -e "s/Audio;/AudioVideo;/" \
+		"${S}/usr/share/applications/${MY_PN}.desktop" || die
+
+	sed -i -e "s|/opt/Яндекс Музыка|/${YANDEX_HOME}|" "${S}/${YANDEX_HOME}"/resources/apparmor-profile || die
+
+	gunzip "usr/share/doc/${PF}/changelog.gz" || die "Failed to decompress docs"
+
+	rm "${S}/${YANDEX_HOME}"/resources/app-update.yml || die
+
+	pushd "${YANDEX_HOME}/locales" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	patchelf --remove-rpath "${S}/${YANDEX_HOME}/chrome-sandbox" || die "Failed to fix library rpath (chrome-sandbox)"
+	patchelf --remove-rpath "${S}/${YANDEX_HOME}/${MY_PN}" || die "Failed to fix library rpath (yandexmusic)"
+}
+
+src_install() {
+	insinto /opt
+	doins -r opt/*
+
+	insinto /usr
+	doins -r usr/*
+
+	make_wrapper ${PN} "/${YANDEX_HOME}/${MY_PN}" "" "/${YANDEX_HOME}" "/opt/bin/"
+
+	fowners root:root "/${YANDEX_HOME}/${MY_PN}"
+	fperms 4711 "/${YANDEX_HOME}/chrome-sandbox"
+	pax-mark m "${ED}${YANDEX_HOME}/chrome-sandbox"
+	fperms 755 "/${YANDEX_HOME}/${MY_PN}"
+}