dev-python/pydantic: Data parsing and validation using type hints

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@riseup.net>

dev-python/pydantic/Manifest

@@ -0,0 +1 @@
+DIST pydantic-1.5.1.tar.gz 233727 BLAKE2B ef41cf8d65d2839444e6457b6f48442d1d1ddee506cc7a75f79dd173e7cf9908c7d2ef1d4f70ddfdf7ba00ad7af7c81697a3e3e03cf058a0494b7d2c5fb874a7 SHA512 beadba0f57bd669ac97f4d7288cdf9598f6c791f46258ba75a3ec93361ebba010d7b1784e8b50534b12f9fb3606e8cc0cbbc7a9321a1d9a6a29e1e73a057f9c4

dev-python/pydantic/metadata.xml

@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+	<maintainer type="person">
+		<email>andrewammerlaan@riseup.net</email>
+		<name>Andrew Ammerlaan</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">samuelcolvin/pydantic</remote-id>
+		<remote-id type="pypi">pydantic</remote-id>
+	</upstream>
+</pkgmetadata>

dev-python/pydantic/pydantic-1.5.1.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+DOCBUILDER="mkdocs"
+DOCDEPEND="
+	dev-python/mkdocs-material
+	dev-python/mkdocs-exclude
+	dev-python/markdown-include
+"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="Data parsing and validation using Python type hints"
+HOMEPAGE="https://github.com/samuelcolvin/pydantic"
+SRC_URI="https://github.com/samuelcolvin/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+
+distutils_enable_tests pytest
+
+BDEPEND="dev-python/cython"
+
+DEPEND="test? (
+	dev-python/mypy[${PYTHON_USEDEP}]
+	dev-python/pytest-mock[${PYTHON_USEDEP}]
+)"
+
+RDEPEND="
+	>=dev-python/devtools-0.5.1[${PYTHON_USEDEP}]
+	>=dev-python/email-validator-1.0.5[${PYTHON_USEDEP}]
+	>=dev-python/python-dotenv-0.13.0[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/dataclasses[${PYTHON_USEDEP}]' python3_6)
+"
+
+python_prepare_all() {
+	# AssertionError: assert 'pydantic-1.5.1.tar.gz' == 'config a'
+	sed -i -e 's:test_config_file_settings_nornir:_&:' \
+		tests/test_settings.py || die
+
+	distutils-r1_python_prepare_all
+}