dev-python/trio: Python library for async concurrency and I/O

Package-Manager: Portage-2.3.93, Repoman-2.3.20
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@riseup.net>

dev-python/trio/Manifest

@@ -0,0 +1 @@
+DIST trio-0.13.0.tar.gz 441925 BLAKE2B c452a0d91d44c651d33399cf5cb64ae05283466732df5332a3319b02fdf9ed73e88fc105b65aeeea39f923c0eecafe842a9e328cbea88424304a7708f8ec703d SHA512 c2f64e71aa59ed0ba5878fda56e5be2c7c434324fa0ace33caf1487fd990dfc63ffda8a20f1586e2175b6b41db51e9b9023e44c367337526263c9a32d98f7ce6

dev-python/trio/metadata.xml

@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+    <maintainer type="person">
+        <email>andrewammerlaan@riseup.net</email>
+        <name>Andrew Ammerlaan</name>
+    </maintainer>
+</pkgmetadata>

dev-python/trio/trio-0.13.0.ebuild

@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1 linux-info
+
+DESCRIPTION="Python library for async concurrency and I/O"
+HOMEPAGE="https://github.com/python-trio/trio"
+SRC_URI="https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0 MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="dev-python/async_generator[${PYTHON_USEDEP}]
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/outcome[${PYTHON_USEDEP}]
+	dev-python/sniffio[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]"
+
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep 'dev-python/contextvars[${PYTHON_USEDEP}]' python3_6)"
+
+BDEPEND="test? ( >=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
+		dev-python/jedi[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		dev-python/yapf[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source
+
+python_prepare_all() {
+	# Disable tests require IPv6
+	if ! linux_config_exists || ! linux_chkconfig_present IPV6; then
+		sed -i  -e "/for family in/s/, AF_INET6//" \
+			-e "/test_getaddrinfo/i@pytest.mark.skip(reason='no IPv6')" \
+			trio/tests/test_socket.py || die "sed failed for test_socket.py"
+	fi
+	distutils-r1_python_prepare_all
+}