sys-apps/ugrep: add 7.2.0

Signed-off-by: Ada Ahmed <yretenai@gmail.com>

sys-apps/ugrep/Manifest

@@ -1 +1,2 @@
 DIST ugrep-5.1.4.tar.gz 6280906 BLAKE2B 3f6e1a20ec9a5a012d3152562d1792a6c4c49dd0874976128ea408e39269ac6df60f6879e631b8471594c2ed840c46b68de0ce5b0e6f5197b665783e39bbde39 SHA512 d746c77a22a98c2719cc7b443351a3d27f0f2712a2be483596965cc2b6127f28b9e564ca32db1fea950a6315053c89440912d4b7311073bd97d7702f02521378
+DIST ugrep-7.2.0.tar.gz 7121849 BLAKE2B 99ee0d032cbbfa5c3f534c922681c4119a3aa431b3c3d78a32967bf32a53267b09baf2c630c842bf6f838f1b6d08e1edf82b4f6d4c31253c852f969691fedd43 SHA512 fd877d367602b24f2d2131fdb32b5e1421d704343420252292f7b765a8676c11e2677acc931c417b5135a81c69405fce942cc144ec0670ce7f75687baf4f3767

sys-apps/ugrep/ugrep-7.2.0.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit shell-completion
+
+DESCRIPTION="A fast, drop-in replacement for GNU grep"
+HOMEPAGE="https://ugrep.com/"
+SRC_URI="https://github.com/Genivia/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+CPU_USE="cpu_flags_arm_neon cpu_flags_x86_avx2 cpu_flags_x86_sse2"
+IUSE="7zip brotli boost bzip2 bzip3 +lzma lz4 +mmap +pcre2 +zlib zstd ${CPU_USE}"
+
+COMMON_DEPEND="
+	brotli? ( app-arch/brotli )
+	boost? ( dev-libs/boost )
+	bzip3? ( app-arch/bzip3 )
+	bzip2? ( app-arch/bzip2 )
+	lz4? ( app-arch/lz4 )
+	lzma? ( app-arch/xz-utils )
+	pcre2? ( dev-libs/libpcre2 )
+	zlib? ( sys-libs/zlib )
+	zstd? ( app-arch/zstd )
+"
+
+RDEPEND="${COMMON_DEPEND}"
+
+DEPEND="
+	${COMMON_DEPEND}
+	virtual/pkgconfig
+"
+
+REQUIRED_USE="?? ( boost pcre2 )"
+
+src_configure() {
+	local myeconfargs=(
+		$(usev !cpu_flags_arm_neon '--disable-neon')
+		$(usev !cpu_flags_x86_avx2 '--disable-avx2')
+		$(usev !cpu_flags_x86_sse2 '--disable-sse2')
+
+		$(use_enable 7zip)
+		$(use_enable mmap)
+
+		$(use_with boost "boost-regex")
+		$(use_with brotli)
+		$(use_with bzip2 "bzlib")
+		$(use_with bzip3)
+		$(use_with pcre2)
+		$(use_with lzma)
+		$(use_with lz4)
+		$(use_with zlib)
+		$(use_with zstd)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	dobashcomp "${S}"/completions/bash/ug "${S}"/completions/bash/ugrep-indexer
+	dofishcomp "${S}"/completions/fish/*.fish
+	dozshcomp "${S}"/completions/zsh/_*
+}
+
+src_test() {
+	# emake check is run first by default in Portage but
+	# that doesn't actually run the tests, emake test does
+	emake test
+}