diff --git a/gnome-extra/extension-manager/Manifest b/gnome-extra/extension-manager/Manifest
index 2fb0310db3..f9970ef283 100644
--- a/gnome-extra/extension-manager/Manifest
+++ b/gnome-extra/extension-manager/Manifest
@@ -1,2 +1,3 @@
 DIST extension-manager-0.6.1.tar.gz 2445709 BLAKE2B a36db9d0721f090ce8030f3898dd3fa8cfdc00d61bee73fc840482b05304bd1a99fda893740a704007cd8e5e9a14b40ac4b0a12764e4cb731d8a48c3f078c98c SHA512 384b8e6241bc8a5d2731a80a3603a995fd279d4df42af2510cb1e718b8b28c955afeed324a36be665f81bcce1c4e62cc18ae093334bfcb08989fdb3271a2ae42
 DIST extension-manager-0.6.3.tar.gz 1901186 BLAKE2B 3c29c45979915fc9cd76a890a8a2f8e42e4d8ae9249ba17f23acbe2207b9905aa56e424e33dd6379e4fe0eac7a4b54b25db73822557043e960a5ff8511b08966 SHA512 727c824b16b178a5e4de749e7c03098404fb0e57feecc6f0693f0fac3b657f6496e906da911ad5e136376d15191323a1d730d3237d14e578a76d0a44bd0a92cf
+DIST extension-manager-0.6.5.tar.gz 1841347 BLAKE2B 29b70bea51c6b3ea37faad605338d4bee756fa0cc66421b6e11829e5c8a81511b81ebb7885ca1024abf70a5a33c4e0acaaaed34143ee01101530e61ad7360ad4 SHA512 95adb3b7f7cc7b4df57fef70b6a57af16284f3d064f0fbe8f75e09029a0fc6beb3bc3f38fdbe21348f1a65fbe66e8ee92470b8d0e577bd54a47a6e28952df009
diff --git a/gnome-extra/extension-manager/extension-manager-0.6.5.ebuild b/gnome-extra/extension-manager/extension-manager-0.6.5.ebuild
new file mode 100644
index 0000000000..b74db09b0a
--- /dev/null
+++ b/gnome-extra/extension-manager/extension-manager-0.6.5.ebuild
@@ -0,0 +1,83 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson xdg
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mjakeman/extension-manager.git"
+else
+	SRC_URI="https://github.com/mjakeman/extension-manager/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="A native tool for browsing, installing, and managing GNOME Shell Extensions"
+HOMEPAGE="https://mattjakeman.com/apps/extension-manager"
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+BDEPEND="
+	dev-libs/glib:2
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libxml2:=
+	gui-libs/gtk:4[introspection]
+	>=gui-libs/libadwaita-1.8.0:1[introspection]
+	net-libs/libsoup:3.0
+"
+
+DEPEND="
+	${RDEPEND}
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dpackage="ebuild"
+		-Ddistributor="Gentoo GURU <guru-bugs@gentoo.org>"
+
+		# sys-libs/libbacktrace has been last-rited in ::gentoo
+		# and is thus unavailable
+		-Dbacktrace=false
+	)
+	if has live ${PROPERTIES}; then
+		# Produce a development build for live ebuild
+		emesonargs+=( -Ddevelopment=true )
+	fi
+	meson_src_configure
+}
+
+# Tests are skipped because as of version 0.3.0, the tests only validate
+# resource files and do not verify any functionality of the program.  Those
+# validations are either already handled by QA checks or not relevant on
+# Gentoo.  For more information about the rationale, please refer to:
+# https://github.com/gentoo/guru/commit/f896bee213fbb62c70e818c1bf503fee2a41919a#comments
+#
+# If tests are to be executed in the future because the upstream adds
+# functionality tests or for other reasons, and should there be no convenient
+# way to skip the validations, the following variable values need to be set:
+#
+# IUSE="test"
+# RESTRICT="!test? ( test )"
+# BDEPEND="test? ( dev-libs/appstream-glib dev-util/desktop-file-utils )"
+src_test() {
+	:
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}