app-admin/vaultwarden: update to 1.33.2 & sync live

* sync live ebuild to 1.32.7 ebuild (LICENSE var, default sqlite,
RDEPEND)
* Force users to use -bin variant of cli & web clients as source
variants are planned for removal from tree

Signed-off-by: Rahil Bhimjiani <me@rahil.rocks>

app-admin/vaultwarden/Manifest

@@ -4,3 +4,6 @@ DIST vaultwarden-1.32.5.tar.gz 623393 BLAKE2B 61bdf57c16f9eb7940c399bf29dbc06b8a
 DIST vaultwarden-1.32.7-docs.tar.xz 703140 BLAKE2B 6bca8f3e03b73d2bc921cc7f91df7bf5199a6267f7cd34e5f183d04d29d29aeb6d6973c61611ee4a18bbe2e8d3627682c018a3af2411497c140f772c977bae5b SHA512 2e865e3cc68a58227b2d5d99fd2292a4f6ddecce3dccbda99c896a1a83afd2020d0252f2104988099a8f564e20b67e2b09ce82923594bf6bafa2c91736ee057b
 DIST vaultwarden-1.32.7-vendor.tar.xz 57393432 BLAKE2B 1dccb4ea8887de90b5dbdb56aa40f4f5d9d670c0b5b1adc19eebd48da05768bb7518fd04638b3630228761474d1ff5015001ca47a94d0ab0677d3ca426837d48 SHA512 6642638c4689b86f68ac7571bcc97139d201c84aa1bfefe78b1ccdb1bd2a6ff758f123a46c1eef14fc95888220ac184d9c911ed0ef18da352a2a80650a65e064
 DIST vaultwarden-1.32.7.tar.gz 628227 BLAKE2B aaf782cdea3c5ad1aca31ec7e40e70df731377d4f8bbd8b752a7aea1b26660feb69c65101fc4597bcbb48d37931e946a45a05d76be3050a538a04f78664db1df SHA512 906f082c9609a52161156b0f5330c197971ffae51d308f8df86f34841b91293394518079e353b06914e5a762555cda37038faa607d1c4893530fdd196688d196
+DIST vaultwarden-1.33.2-deps.tar.xz 55221392 BLAKE2B e3fc484ef3c1608332130498721240e968b83b9c80e10a139623780dbe6b46d4fa3f75ce926175f5d708e831ab6c211a10e55b5cf4b7cbeae496818a1de1a226 SHA512 2f15d3c4d404efc23afa602b00eb003d067c380d0a84e7bfc03345054340dade54005064b80a9e04e63965751d6be9f631142547ccbb16952bb204d6cd206f8b
+DIST vaultwarden-1.33.2-docs.tar.xz 75976 BLAKE2B 398487cb7c9b50f5bd60a43e4e2324da0cc4d7757ba0b341142aa18531887267324659a9b874309ef09149bb8f5f0758942ea2a619a6995a5dc663873f3d626f SHA512 e7d7c1c7a0171e714b237eddb0a0c52f941e281e330f984557bd01dd04b4e0fb01f60ced4fec385cb736c415946c09170706d86422706ab2776db45f08500199
+DIST vaultwarden-1.33.2.tar.gz 638237 BLAKE2B 515c8c6ec4ca6d6347f421057bbc8b1509ae789fb8ac88189dffe0380a2034bee8d87660de8b8cab94c710fa1de0ff5d897da48d0077f82d1c0463f977b4afe2 SHA512 51f1d431794f2b4bf1f3b70a66f3fc9329cf74732201faaa0948ac0025f1384a486d0a5c757506068ea822f13c6c5bf10429cfe1a291e4bb154bc2332aba778d

app-admin/vaultwarden/vaultwarden-1.33.2.ebuild

@@ -0,0 +1,133 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cargo check-reqs readme.gentoo-r1 systemd tmpfiles
+
+DESCRIPTION="Unofficial Bitwarden compatible password manager server written in Rust"
+HOMEPAGE="https://github.com/dani-garcia/vaultwarden"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/dani-garcia/vaultwarden.git"
+else
+	SRC_URI="
+	https://github.com/dani-garcia/vaultwarden/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/rahilarious/gentoo-distfiles/releases/download/${P}/deps.tar.xz -> ${P}-deps.tar.xz
+	https://github.com/rahilarious/gentoo-distfiles/releases/download/${P}/wiki.tar.xz -> ${P}-docs.tar.xz
+"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="AGPL-3"
+# Dependent crate licenses
+LICENSE+=" 0BSD Apache-2.0 BSD ISC MIT MPL-2.0 Unicode-3.0"
+
+SLOT="0"
+IUSE="cli mysql postgres +sqlite web"
+REQUIRED_USE="|| ( mysql postgres sqlite )"
+
+RDEPEND="
+	acct-user/vaultwarden
+	acct-group/vaultwarden
+	dev-libs/openssl:=
+	cli? ( app-admin/bitwarden-cli-bin )
+	mysql? ( dev-db/mysql-connector-c:= )
+	postgres? ( dev-db/postgresql:* )
+	sqlite? ( dev-db/sqlite:3 )
+	web? ( www-apps/vaultwarden-web-bin )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+QA_FLAGS_IGNORED="usr/bin/${PN}"
+QA_PRESTRIPPED="usr/bin/${PN}"
+ECARGO_VENDOR="${WORKDIR}/vendor"
+
+PATCHES=(
+	"${FILESDIR}"/vaultwarden-envfile-1.30.3.patch
+)
+
+CHECKREQS_MEMORY=3G
+CHECKREQS_DISK_BUILD=2G
+
+DOC_CONTENTS="\n
+	Configuration file: /etc/${PN}.env\n
+	Data directory: /var/lib/${PN}\n
+	\n
+	MySQL & PostgreSQL users must set DATABASE_URL in config\n
+	\n
+	Default server: http://0.0.0.0:8000\n
+	Admin interface: http://0.0.0.0:8000/admin
+"
+
+pkg_setup() {
+	check-reqs_pkg_setup
+	rust_pkg_setup
+}
+
+src_unpack() {
+	if [[ ${PV} == 9999* ]]; then
+		# clone vaultwarden
+		git-r3_src_unpack
+
+		# clone vaultwarden.wiki
+		EGIT_REPO_URI="https://github.com/dani-garcia/vaultwarden.wiki.git"
+		EGIT_CHECKOUT_DIR="${WORKDIR}/${PN}.wiki"
+		git-r3_src_unpack
+
+		cargo_live_src_unpack
+	else
+		cargo_src_unpack
+	fi
+}
+
+src_prepare() {
+	default
+	if [[ ${PV} != 9999* ]]; then
+		cat <<-'EOF' >> "${ECARGO_HOME}"/config.toml || die
+			[source."git+https://github.com/BlackDex/yubico-rs?rev=00df14811f58155c0f02e3ab10f1570ed3e115c6"]
+			git = "https://github.com/BlackDex/yubico-rs"
+			rev = "00df14811f58155c0f02e3ab10f1570ed3e115c6"
+			replace-with = "gentoo"
+		EOF
+	fi
+	use web && { sed -i -e 's|^WEB_VAULT_ENABLED=false|WEB_VAULT_ENABLED=true|g;' .env.template || die; }
+}
+
+src_configure() {
+	local myfeatures=(
+		$(usev sqlite)
+		$(usev mysql)
+		$(usev postgres postgresql )
+	)
+	cargo_src_configure
+}
+
+src_compile() {
+	# https://github.com/dani-garcia/vaultwarden/blob/main/build.rs
+	[[ ${PV} != 9999* ]] && export VW_VERSION="${PV}"
+	cargo_src_compile
+}
+
+src_install() {
+	dobin target/*/*/"${PN}"
+	systemd_newunit "${FILESDIR}"/vaultwarden-1.30.3.service "${PN}".service
+	newinitd "${FILESDIR}"/vaultwarden-1.30.3.initd "${PN}"
+	newtmpfiles "${FILESDIR}"/vaultwarden-tmpfiles-1.30.3.conf "${PN}".conf
+	insinto /etc
+	newins .env.template "${PN}".env
+	dosym -r /etc/"${PN}".env /etc/conf.d/"${PN}"
+	keepdir /var/lib/"${PN}"
+
+	readme.gentoo_create_doc
+	einstalldocs
+	dodoc -r ../"${PN}".wiki/*
+}
+
+pkg_postinst() {
+	tmpfiles_process "${PN}".conf
+	readme.gentoo_print_elog
+}

app-admin/vaultwarden/vaultwarden-9999.ebuild

@@ -1,4 +1,4 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -20,23 +20,23 @@ else
 	KEYWORDS="~amd64"
 fi
 
-# main
 LICENSE="AGPL-3"
-# deps
+# Dependent crate licenses
-LICENSE+=" 0BSD Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD ISC MIT MPL-2.0 Unicode-DFS-2016"
+LICENSE+=" 0BSD Apache-2.0 BSD ISC MIT MPL-2.0 Unicode-3.0"
 
 SLOT="0"
-IUSE="cli mysql postgres sqlite web"
+IUSE="cli mysql postgres +sqlite web"
 REQUIRED_USE="|| ( mysql postgres sqlite )"
 
 RDEPEND="
 	acct-user/vaultwarden
 	acct-group/vaultwarden
-	cli? ( || ( app-admin/bitwarden-cli app-admin/bitwarden-cli-bin  ) )
+	dev-libs/openssl:=
+	cli? ( app-admin/bitwarden-cli-bin )
 	mysql? ( dev-db/mysql-connector-c:= )
 	postgres? ( dev-db/postgresql:* )
 	sqlite? ( dev-db/sqlite:3 )
-	web? ( || ( www-apps/vaultwarden-web www-apps/vaultwarden-web-bin  ) )
+	web? ( www-apps/vaultwarden-web-bin )
 "
 
 DEPEND="${RDEPEND}"
@@ -86,6 +86,14 @@ src_unpack() {
 
 src_prepare() {
 	default
+	if [[ ${PV} != 9999* ]]; then
+		cat <<-'EOF' >> "${ECARGO_HOME}"/config.toml || die
+			[source."git+https://github.com/BlackDex/yubico-rs?rev=00df14811f58155c0f02e3ab10f1570ed3e115c6"]
+			git = "https://github.com/BlackDex/yubico-rs"
+			rev = "00df14811f58155c0f02e3ab10f1570ed3e115c6"
+			replace-with = "gentoo"
+		EOF
+	fi
 	use web && { sed -i -e 's|^WEB_VAULT_ENABLED=false|WEB_VAULT_ENABLED=true|g;' .env.template || die; }
 }
 
@@ -105,7 +113,7 @@ src_compile() {
 }
 
 src_install() {
-	dobin target/*/"${PN}"
+	dobin target/*/*/"${PN}"
 	systemd_newunit "${FILESDIR}"/vaultwarden-1.30.3.service "${PN}".service
 	newinitd "${FILESDIR}"/vaultwarden-1.30.3.initd "${PN}"
 	newtmpfiles "${FILESDIR}"/vaultwarden-tmpfiles-1.30.3.conf "${PN}".conf