www-client/torbrowser-launcher: new package, add 0.3.9

Signed-off-by: Pavel Sobolev <contact@paveloom.dev>

www-client/torbrowser-launcher/Manifest

@@ -0,0 +1 @@
+DIST torbrowser-launcher-0.3.9.tar.bz2 200584 BLAKE2B 901620e383d3c31b6a80961bcf9ea3f737a5ec50ae836fd943bca67d4a3c86ff1f25c174e47f1689b6e70461b55f937a69ab275a0dbb42175969da112eda811c SHA512 d6b215fd89400c7738164c8bce33c44b7c44add25bb0c37da96ec03ff6e07246113c7b0d58b263c99033f09fb438d8c23da24b0d6f540c5610e3d4010ea41a28

www-client/torbrowser-launcher/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <name>Pavel Sobolev</name>
+    <email>contact@paveloom.dev</email>
+  </maintainer>
+  <upstream>
+    <bugs-to>https://gitlab.torproject.org/tpo/applications/torbrowser-launcher/-/issues</bugs-to>
+  </upstream>
+</pkgmetadata>

www-client/torbrowser-launcher/torbrowser-launcher-0.3.9.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 xdg
+
+DESCRIPTION="A program to help you securely download and run Tor Browser"
+HOMEPAGE="https://gitlab.torproject.org/tpo/applications/torbrowser-launcher"
+SRC_URI="https://gitlab.torproject.org/tpo/applications/torbrowser-launcher/-/archive/v${PV}/${PN}-v${PV}.tar.bz2 -> ${P}.tar.bz2"
+
+S="${WORKDIR}/${PN}-v${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="wayland"
+
+# Copied from `www-client/firefox-bin::gentoo`'s `RDEPEND`
+BROWSER_RDEPEND="
+	|| (
+		media-libs/libpulse
+		media-sound/apulse
+	)
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	>=dev-libs/glib-2.26:2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	>=media-libs/freetype-2.4.10
+	sys-apps/dbus
+	virtual/freedesktop-icon-theme
+	>=x11-libs/cairo-1.10[X]
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.11:3[X,wayland?]
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libxcb
+	>=x11-libs/pango-1.22.0
+"
+RDEPEND="
+	dev-python/gpgmepy[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pyside:6[core,gui,widgets,${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+
+	app-crypt/gnupg
+	net-vpn/tor
+
+	${BROWSER_RDEPEND}
+"
+DEPEND="
+	dev-python/distro[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	sys-devel/gettext
+"
+
+distutils_enable_tests import-check
+
+pkg_postinst() {
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+}