diff --git a/dev-libs/open62541/Manifest b/dev-libs/open62541/Manifest
index 00c9a9c0a2..33ba989dc7 100644
--- a/dev-libs/open62541/Manifest
+++ b/dev-libs/open62541/Manifest
@@ -1 +1,2 @@
 DIST open62541-1.4.6.tar.gz 4216130 BLAKE2B f9830a96a85946c4820269120e02ce4b8c886851c6f76165d6515ee839acdd93349e5674cde437ca7ef7ea6734e4d0944bfec8435a65a44b409e41b89fea54b6 SHA512 639612c72a551c98c1ca68a4dc226201592f52c98969a80a7c5c1b5f2c811f8bd3fd8c2865034901ff9467e6675580391a80045f5da99f3b6ffed45f9a0ec1bd
+DIST open62541-1.4.8.tar.gz 4216390 BLAKE2B f77c7b4cccd361f88a344bb88762051d155a71891757d57c3c3b24713c1039118a8dc644a5c7acc436c8318f9743d39212c93fb2e578d53ff4cdef45a45f3b46 SHA512 2226faa6bdc577b54fcaf995783b032b02f9c0a8ccde8da2d47bc309d3ae391d68eabbf4ddb9afe487dbe82a5b325eb7a09d29f4c8a2fe6f2bbda99e050c5653
diff --git a/dev-libs/open62541/open62541-1.4.8.ebuild b/dev-libs/open62541/open62541-1.4.8.ebuild
new file mode 100644
index 0000000000..a4226411bf
--- /dev/null
+++ b/dev-libs/open62541/open62541-1.4.8.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit cmake python-single-r1
+
+DESCRIPTION="Open source C implementation of OPC UA"
+HOMEPAGE="https://www.open62541.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc examples mbedtls pubsub openssl tools"
+# Requires network access
+RESTRICT="test"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	?? ( mbedtls openssl )
+"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? (
+		media-gfx/graphviz
+		$(python_gen_cond_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+		')
+	)
+"
+DEPEND="
+	mbedtls? ( net-libs/mbedtls:= )
+	openssl? ( dev-libs/openssl:0= )
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	${DEPEND}
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=ON
+		-DOPEN62541_VERSION=v${PV}
+		-DUA_BUILD_EXAMPLES=OFF
+		-DUA_BUILD_TOOLS=$(usex tools)
+		-DUA_BUILD_UNIT_TESTS=OFF
+		-DUA_ENABLE_HARDENING=OFF
+		-DUA_ENABLE_PUBSUB=$(usex pubsub)
+		-DUA_ENABLE_PUBSUB_INFORMATIONMODEL=$(usex pubsub)
+		-DUA_FORCE_WERROR=OFF
+	)
+
+	use mbedtls && mycmakeargs+=(-DUA_ENABLE_ENCRYPTION=MBEDTLS)
+	use openssl && mycmakeargs+=(-DUA_ENABLE_ENCRYPTION=OPENSSL)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_build doc
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( "${WORKDIR}"/${P}_build/doc/. )
+	cmake_src_install
+
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples/
+	fi
+}
+
+src_test() {
+	cmake_src_test -j1
+}