dev-python/factory-boy: new package, add 3.3.3

Signed-off-by: Katalin Rebhan <kat@knifepoint.net>

dev-python/factory-boy/Manifest

@@ -0,0 +1 @@
+DIST factory-boy-3.3.3.gh.tar.gz 148641 BLAKE2B 702685927a3ef3ae1f930ce088dce32908519ef0a124e2589569180026a1ce0df4b0e04912ed5bc767a397845a23ca64365e675e45a0d7a6921987e2062ed38e SHA512 484b4b3db3bb88ccc63793ea5630c5b138208d9a802a2be77ed349fab504c0e548b9b4fa6e80615913c917532f3b50e8018645122d1e90acaf170666d4f8dd5f

dev-python/factory-boy/factory-boy-3.3.3.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..15} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="Versatile test fixtures replacement based on thoughtbot's factory_bot"
+HOMEPAGE="
+	https://github.com/FactoryBoy/factory_boy
+	https://pypi.org/project/factory-boy/"
+SRC_URI="https://github.com/FactoryBoy/factory_boy/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+S="${WORKDIR}/factory_boy-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND=">=dev-python/faker-0.7.0[${PYTHON_USEDEP}]"
+
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}] )"
+
+EPYTEST_PLUGINS=( pytest-django )
+EPYTEST_IGNORE=(
+	# flask_sqlalchemy not packaged
+	examples/flask_alchemy/test_demoapp.py )
+EPYTEST_DESELECT=(
+	# completely broken ("setup_test_environment() was already called and can't
+	# be called again without first calling teardown_test_environment().")
+	tests/test_django.py )
+distutils_enable_tests pytest
+
+src_install() {
+	distutils-r1_src_install
+
+	# Package installs broken "ChangeLog" symlink which points to changelog.rst,
+	# so let's install that instead.
+	rm "${ED}"/usr/share/doc/"${PF}"/ChangeLog || die
+	dodoc docs/changelog.rst
+}

dev-python/factory-boy/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<name>Katalin Rebhan</name>
+		<email>kat@knifepoint.net</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">factory-boy</remote-id>
+		<remote-id type="github">FactoryBoy/factory_boy</remote-id>
+	</upstream>
+</pkgmetadata>