kde-apps/kaidan: new package

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Anna Vyalkova <cyber@sysrq.in>

kde-apps/kaidan/Manifest

@@ -0,0 +1 @@
+DIST kaidan-0.7.0.tar.xz 516684 BLAKE2B 6ee2f6696b1fca2ec564563e13c621f63edc8696d4b14ec22157adef611d5ba9d2d522bd960d1becc16a720851263503251d5a1f850af409daf439165a23839f SHA512 89389db3dfbc6acfae252c6fad2492a997760495f9a55d6f56bbf0f49832fcbff35548ba89dc3f24e6ff05b0c4b1ee0242566ca1c7f662fc096b13b37f99af94

kde-apps/kaidan/kaidan-0.7.0.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="true"
+KFMIN=5.67.0
+QTMIN=5.14.0
+inherit ecm
+
+DESCRIPTION="A simple, user-friendly Jabber/XMPP client for every device!"
+HOMEPAGE="https://www.kaidan.im"
+SRC_URI="mirror://kde/unstable/${PN}/${PV}/${P}.tar.xz"
+
+LICENSE="Apache-2.0 CC-BY-SA-4.0 GPL-3+ GPL-3-with-openssl-exception MIT"
+SLOT="5"
+KEYWORDS="~amd64 ~x86"
+IUSE="kde nls"
+
+BDEPEND="
+	nls? ( >=dev-qt/linguist-tools-${QTMIN}:5 )
+"
+DEPEND="
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtlocation-${QTMIN}:5
+	>=dev-qt/qtmultimedia-${QTMIN}:5[qml]
+	>=dev-qt/qtnetwork-${QTMIN}:5[ssl]
+	>=dev-qt/qtpositioning-${QTMIN}:5[qml]
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/qqc2-desktop-style-${KFMIN}:5
+	>=media-libs/zxing-cpp-1.0.8
+	>=net-libs/qxmpp-1.2.0
+	kde? ( >=kde-frameworks/knotifications-${KFMIN}:5 )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DI18N=$(usex nls)
+		-DBUILD_TESTS=$(usex test)
+		-DUSE_KNOTIFICATIONS=$(usex kde)
+		# compile QML at build time
+		-DQUICK_COMPILER=ON
+	)
+	ecm_src_configure
+}

kde-apps/kaidan/metadata.xml

@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<upstream>
+		<remote-id type="github">KDE/kaidan</remote-id>
+		<changelog>https://invent.kde.org/network/kaidan/-/raw/master/NEWS</changelog>
+		<bugs-to>https://invent.kde.org/network/kaidan/issues</bugs-to>
+	</upstream>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+</pkgmetadata>