diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 026930fe97..da0d32e5b5 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,2 +1,3 @@
 DIST fastfetch-1.7.2.tar.gz 426097 BLAKE2B 5f9714b735605d4cc4cf8179f048c4cff24db0010f91e080f5e6c0f41329cbc155cdb883775ccb98bda77bfd4efb1f2b79f0adad4a2694d338b0027a31f170b1 SHA512 9f3051d8b9bc22ef93a2e6993c553c5a18d475c8cbb16a63087706aa823a0a4806c49aabb3cdbf5f240f9c9325ea5cb7db2498adcc87c9e44b77d26f6c28a39f
 DIST fastfetch-1.7.5.tar.gz 449086 BLAKE2B b446abd550208c726d58b5e282107f5f7492bbd04439efda19194fd74bf87d2760a845c78431de124b925a52b74de0896197c80f65508fae2704e4786848a303 SHA512 134e088b3faa551108f65e693e8dad3c6def29b0086c86330cc7738854fddb49f30a2cb7cd61c12195723ddd47f33823906af3d8bff746e1da006b6fda45f85b
+DIST fastfetch-1.8.0.tar.gz 495237 BLAKE2B 151f45ea6753dc8333767beebb633732f2d375e4f9ce9019e30c2edbddf0f554864591e4536563df4f12494ce7a3e2e20e7492bcb66de896b1ad080570300378 SHA512 cbba45bb5338adf26bf188184e290fbf1a67791caee1432acd1030bd11622484506c9a5f267f7abca953c3a4f2e7d2ee5725c7e178a6284fdbfe05633b9db387
diff --git a/app-misc/fastfetch/fastfetch-1.8.0.ebuild b/app-misc/fastfetch/fastfetch-1.8.0.ebuild
new file mode 100644
index 0000000000..c9038f0156
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-1.8.0.ebuild
@@ -0,0 +1,89 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Fast system information tool"
+HOMEPAGE="https://github.com/LinusDierheimer/fastfetch"
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/LinusDierheimer/fastfetch.git"
+	[[ ${PV} == *9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *d ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/LinusDierheimer/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="X chafa dbus gnome imagemagick opencl opengl osmesa pci sqlite vulkan wayland xcb xfce xrandr"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+RDEPEND="
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pci? ( sys-apps/pciutils )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? ( media-libs/vulkan-loader )
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_LIBPCI=$(usex pci)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_ZLIB=yes
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_LIBCJSON=no
+	)
+
+	cmake_src_configure
+}