sys-apps/coolercontrol-liqctld: add 2.1.0, new package

Signed-off-by: Paul Zander <negril.nx+gentoo@gmail.com>

sys-apps/coolercontrol-liqctld/Manifest

@@ -0,0 +1 @@
+DIST coolercontrol-2.1.0.tar.bz2 15732132 BLAKE2B e90692b6b5d9b99ebc2bd26d519f9311600664c8296d1264ccd3d1d81b70e80ffa353eeae65a55e8398fc6e992dec0e7c451f22fe39bc0eec9cee1364a9004e8 SHA512 975877f0bbea06e294ff7b1d07ad7c12543b4dfc044e1500daf4658d3a9b13e49c52a66847b81f4d81d6c8604b6e3526c9fdc93f0a830650f8e0b3b081cefd81

sys-apps/coolercontrol-liqctld/coolercontrol-liqctld-2.1.0.ebuild

@@ -0,0 +1,39 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..13} )
+inherit distutils-r1 systemd
+
+DESCRIPTION="Monitor and control your cooling and other devices (liqctld)"
+HOMEPAGE="https://gitlab.com/coolercontrol/coolercontrol"
+SRC_URI="
+	https://gitlab.com/coolercontrol/coolercontrol/-/archive/${PV}/coolercontrol-${PV}.tar.bz2
+"
+S="${WORKDIR}/coolercontrol-${PV}/${PN}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	app-misc/liquidctl[${PYTHON_USEDEP}]
+	dev-python/fastapi[${PYTHON_USEDEP}]
+	dev-python/setproctitle[${PYTHON_USEDEP}]
+	dev-python/uvicorn[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	pushd .. >/dev/null || die
+	default
+	popd >/dev/null || die
+}
+
+python_install_all() {
+	doinitd ../packaging/openrc/init.d/coolercontrol-liqctld
+	doconfd ../packaging/openrc/conf.d/coolercontrol-liqctld
+
+	systemd_dounit ../packaging/systemd/coolercontrol-liqctld.service
+}

sys-apps/coolercontrol-liqctld/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>negril.nx+gentoo@gmail.com</email>
+		<name>Paul Zander</name>
+	</maintainer>
+	<upstream>
+		<doc>https://docs.coolercontrol.org/</doc>
+		<remote-id type="gitlab">coolercontrol/coolercontrol</remote-id>
+	</upstream>
+</pkgmetadata>