dev-python/pg8000: add 1.29.2, drop 1.26.1

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-python/pg8000/Manifest

@@ -1,2 +1,2 @@
-DIST pg8000-1.26.1.tar.gz 116994 BLAKE2B 4db3186e72afb2e2fae441c1bbb974768e0064276f1ad571316a531cbc590edfcca4c3f4ef1fd493e80e7ebd1817bee354413ea158ec191434e8530007af0ee3 SHA512 d085d4992be18868da6b6f67efcb1e5f41cd05a13b0f4361685e5e8ada14af02ef4ee17558809b447a118cf8380fab13e8932d49fd14d2ee2472b191f8531289
 DIST pg8000-1.29.1.tar.gz 92221 BLAKE2B a1e43f445848283472b0aee84f05d3e1c0f8f2d6b8c619789f9e1d961dae240c9ebfb8a1fb22af55f4635bb89f036f8dd1ece477b3b68bff5c1b68ccac32b0b4 SHA512 27ced0ae82e522fabdf3a69b07927223695a7c5658f56f75dbfa43f6923b7a914ec54143421324839c07850e10f5f61ca9bc31155af3e4e600429a1889aedea7
+DIST pg8000-1.29.2.tar.gz 92786 BLAKE2B de39587bb34f21b5c9c4477dd5380d3f790091970867a342c87fac91383e68e8b06e883f25130eefbb88d929d869018881558750f735c81615fbcdc96f9c796b SHA512 3e40d254800c7354097372cc58abbd633316e9e9340d02cc20f21a2dc6c87b559a157c9719b6f15cf2d96c393e0c904c6d1310ea9d6367bb808c3c13114ec431

dev-python/pg8000/pg8000-1.26.1.ebuild

@@ -1,34 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..10} )
-
-inherit distutils-r1
-
-DESCRIPTION="A Pure-Python PostgreSQL Driver"
-HOMEPAGE="
-	https://github.com/tlocke/pg8000
-	https://pypi.org/project/pg8000/
-"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-SLOT="0"
-LICENSE="BSD"
-KEYWORDS="~amd64"
-
-RDEPEND=">=dev-python/scramp-1.4.1[${PYTHON_USEDEP}]"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	test? (
-		dev-db/postgresql
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		dev-python/pytest-benchmark[${PYTHON_USEDEP}]
-		dev-python/pytz[${PYTHON_USEDEP}]
-	)
-"
-
-RESTRICT="test" # tests require a running postgresql
-
-distutils_enable_tests pytest

dev-python/pg8000/pg8000-1.29.2.ebuild

@@ -0,0 +1,79 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_PEP517=setuptools
+inherit databases distutils-r1 edo
+
+DESCRIPTION="A Pure-Python PostgreSQL Driver"
+HOMEPAGE="
+	https://github.com/tlocke/pg8000
+	https://pypi.org/project/pg8000/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/scramp-1.4.3[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep "ssl")
+		$(epostgres --get-depend)
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-benchmark[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+	)
+"
+
+SSL_TESTS=(
+	test/dbapi/auth/test_md5_ssl.py
+	test/dbapi/auth/test_scram-sha-256_ssl.p
+	test/legacy/auth/test_md5_ssl.py
+	test/legacy/auth/test_scram-sha-256_ssl.py
+	test/native/auth/test_md5_ssl.py
+	test/native/auth/test_scram-sha-256_ssl.py
+)
+
+EPYTEST_DESELECT=(
+	# traceback doesn't match
+	test/test_readme.py
+	# TODO: ssl tests (need certificates and stuff)
+	"${SSL_TESTS[@]}"
+	# "database doesn't exist" errors
+	test/dbapi/auth/test_gss.py
+	test/legacy/auth/test_gss.py
+	test/native/auth/test_gss.py
+	# too unstable
+	test/native/test_typeconversion.py::test_roundtrip_oid
+)
+
+distutils_enable_tests pytest
+
+python_test_ssl() {
+	epytest "${SSL_TESTS[@]}"
+}
+
+src_test() {
+	epsql() {
+		edo psql -q -h "${sockdir}" -U postgres "${@}"
+	}
+
+	local -x PGPORT="65432"
+	local -x PGPASSWORD="cpsnow"
+	local sockdir=$(epostgres --get-sockdir)
+
+	epostgres --start ${PGPORT}
+	epsql -c "ALTER ROLE postgres WITH PASSWORD '${PGPASSWORD}';"
+	epsql -c "CREATE EXTENSION hstore;"
+	epsql -c "SELECT pg_reload_conf();"
+
+	distutils-r1_src_test
+	epostgres --stop
+}