sci-electronics/sby: add 0.65

Signed-off-by: Huang Rui <vowstar@gmail.com>

sci-electronics/sby/Manifest

@@ -1 +1,2 @@
 DIST sby-0.64.tar.gz 178460 BLAKE2B 3cdda81a75f8a5921162c74a3e425af1e9d5f5cdabf704a27e50ca65fee4dd01d39cd68886051d608e7e4d9e8380b4ad2235b77f58654335e623bf2cb0049968 SHA512 566c87cf2d30a293d318fc1fe6ea25cdea6c0d3f1eb95df438d26875dba87466f23b70d9a3a7aab60322a75c228cc07a4d65f0cfdc5c8c87726f2947c20a2c41
+DIST sby-0.65.tar.gz 178478 BLAKE2B 024ce6d263e145f4d80710e3717350fe3c812b2b5a1235348fb90073e2cd5c81a22944c04bfca21d15ce973b6cb0f0bcb00235a78380154318c5752133acb90e SHA512 75f04bfbb17627282549cea7e62a30a7eca3165819acaddd9791f7d938e088ca8786bd12dbd398e011d098858bc131313e5f163c2575ca838dcda5ef3d8f8526

sci-electronics/sby/sby-0.65.ebuild

@@ -0,0 +1,64 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit python-single-r1
+
+DESCRIPTION="Front-end for Yosys-based formal hardware verification flows"
+HOMEPAGE="https://github.com/YosysHQ/sby"
+SRC_URI="https://github.com/YosysHQ/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test yices2"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/click[${PYTHON_USEDEP}]
+	')
+	sci-electronics/yosys
+	sci-mathematics/z3
+	yices2? ( sci-mathematics/yices2 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/xmlschema[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+src_test() {
+	# Upstream tests race under parallel make (concurrent sqlite WAL access
+	# to shared status_db). Force serial execution.
+	emake -j1 -C tests test
+}
+
+src_install() {
+	# Install Python modules to yosys shared directory
+	insinto /usr/share/yosys/python3
+	doins sbysrc/sby_*.py
+
+	# Install sby_core.py with program prefix substitution
+	sed -e 's|##yosys-program-prefix##|""|' \
+		sbysrc/sby_core.py > "${T}/sby_core.py" || die
+	doins "${T}/sby_core.py"
+
+	# Create the sby launcher script with path and version substitutions
+	# Use absolute path with EPREFIX because python-exec wrapper changes script location
+	local syspath="sys.path += [\"${EPREFIX}/usr/share/yosys/python3\"]"
+	sed -e "s|##yosys-sys-path##|${syspath}|" \
+		-e "s|##yosys-release-version##|release_version = 'SBY ${PV}'|" \
+		sbysrc/sby.py > "${T}/sby" || die
+	python_newscript "${T}/sby" sby
+
+	dodoc README.md
+}