From 3b6502679e347e95992a9d5d75bd4e5d41222148 Mon Sep 17 00:00:00 2001
From: Takuya Wakazono <pastalian46@gmail.com>
Date: Sun, 15 Feb 2026 17:53:17 +0900
Subject: [PATCH] app-text/komikku: add 1.103.0

Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>
---
 app-text/komikku/Manifest               |  1 +
 app-text/komikku/komikku-1.103.0.ebuild | 96 +++++++++++++++++++++++++
 2 files changed, 97 insertions(+)
 create mode 100644 app-text/komikku/komikku-1.103.0.ebuild

diff --git a/app-text/komikku/Manifest b/app-text/komikku/Manifest
index 5a654fe92c..8235a467cd 100644
--- a/app-text/komikku/Manifest
+++ b/app-text/komikku/Manifest
@@ -1 +1,2 @@
 DIST komikku-1.100.0.tar.gz 4704235 BLAKE2B bb0d98919157f9291b94ddf74dd40a9da624c653747084f24c4afd0da45390ab1debf06a6d9b1e58ec2cccf63e63a527e4e094a23136b099340ae9c13b48256d SHA512 79f12563c7c24024f72557f3ac386f82b589f145f19c43280caebac1d43f522406581da975c472fad177cb3ff024eb21cf16ccf06cc4d49f296637586a1189af
+DIST komikku-1.103.0.tar.gz 4750490 BLAKE2B 224b6a14143dd44fed8cbb0a7a828778a7e09cae06afe6d6f05c7cd72694196b912548bf8a0eaa6ad9c8e35d2224c4ae7088a9a199ee42a3b6d6b042d0c27a09 SHA512 68878077cb6dce811db90f9ae20f31eaeaf680238e97c6c327e6dd9695e24781914543a396f1645a8c98cb7d5399058a7ccb2404e5e451501f2261e28d09665a
diff --git a/app-text/komikku/komikku-1.103.0.ebuild b/app-text/komikku/komikku-1.103.0.ebuild
new file mode 100644
index 0000000000..8defaf86e1
--- /dev/null
+++ b/app-text/komikku/komikku-1.103.0.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..14} )
+PYTHON_REQ_USE="sqlite(+),ssl(+)"
+DISTUTILS_USE_PEP517=no
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 meson gnome2-utils xdg
+
+DESCRIPTION="Manga reader for GNOME"
+HOMEPAGE="https://apps.gnome.org/Komikku/"
+SRC_URI="https://codeberg.org/valos/Komikku/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}"
+
+LICENSE="CC0-1.0 CC-BY-4.0 GPL-3+ OFL-1.1"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RESTRICT="test"
+# Depend on a random server that may or may not be accessible.
+#PROPERTIES="test_network"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=gui-libs/gtk-4.18:4
+	>=gui-libs/libadwaita-1.8:1[introspection]
+	net-libs/webkit-gtk:6[introspection]
+"
+RDEPEND="
+	${DEPEND}
+	$(python_gen_cond_dep '
+		>=app-arch/brotli-1.2.0[python,${PYTHON_USEDEP}]
+		dev-python/EbookLib[${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/colorthief[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/piexif[${PYTHON_USEDEP}]
+		>=dev-python/pillow-11.3.0[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		>=dev-python/pyjwt-2.10.1[${PYTHON_USEDEP}]
+		>=dev-python/pypdf-6.4.2[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/rarfile[compressed,${PYTHON_USEDEP}]
+		>=dev-python/requests-2.32.4[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+"
+
+PATCHES=(
+	# x11-libs/gdk-pixbuf-2.44.3 is not packaged yet
+	"${FILESDIR}/${PN}-1.99.0-revert-pixbuf-2.44.3.patch"
+)
+
+EPYTEST_PLUGINS=( pytest-steps )
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# fix broken shebang
+	sed "s|py_installation.full_path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+src_test() {
+	emake setup
+	emake develop
+	emake test
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}