dev-python/factory_boy: version bump 3.1.0, add py3.9

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@riseup.net>

dev-python/factory_boy/factory_boy-3.1.0.ebuild

@@ -0,0 +1,46 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="A fixtures replacement tool"
+HOMEPAGE="https://github.com/FactoryBoy/factory_boy"
+SRC_URI="https://github.com/FactoryBoy/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="dev-python/faker[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/mongoengine[${PYTHON_USEDEP}]
+		dev-python/pillow[jpeg,${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	)
+	doc? (
+		dev-python/factory_boy[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Fix symbolic link QA
+	rm ChangeLog || die "remove failed"
+	cp docs/changelog.rst ChangeLog || die "copy failed"
+
+	# Disable online tests
+	sed -i -e 's:tearDownClass:_&:' \
+		-e 's:test_creation:_&:' \
+		tests/test_mongoengine.py  || die
+
+	distutils-r1_python_prepare_all
+}
+
+distutils_enable_tests --install unittest
+distutils_enable_sphinx docs dev-python/sphinx_rtd_theme