diff --git a/dev-python/dropbox/Manifest b/dev-python/dropbox/Manifest
index ce32650dca..83a2ca7b15 100644
--- a/dev-python/dropbox/Manifest
+++ b/dev-python/dropbox/Manifest
@@ -1 +1,2 @@
 DIST dropbox-12.0.2_p20260506.gh.tar.gz 1152945 BLAKE2B 728a269669ab835541c71068f05c401131fbe1d06f2f095a59e338d83cb5bd2bae674c8c1d050ae252a6af7db60e95b5be28e4b13f16296ecb35b6abd7efc450 SHA512 68ff810162ff945bcbcd9c6e7fb0cbf255b35b0964aa2391377a3cbe928b87a5408abc3cbccf4c9d2d0cde365393faf4e8186da1cff3b2d400732ac110eb404d
+DIST dropbox-12.1.0.gh.tar.gz 1152840 BLAKE2B 61614cefcf4a7bafa5c7f68d906ff6afe772fe9a4a587f0f0eebbd880f152bd191aebccab0dc723c1c58f8fb772b6a956b03312e3b16d94754c21437207fe46b SHA512 8108efcf9bbd979807787bc545b0711e41356dc8a1a421df8eaa643bf0281e339d417e75a48b09ab2f3cd5894cf8c731c21e2d6ab3f5fe75349caf4422c8c28e
diff --git a/dev-python/dropbox/dropbox-12.1.0.ebuild b/dev-python/dropbox/dropbox-12.1.0.ebuild
new file mode 100644
index 0000000000..00958e2a11
--- /dev/null
+++ b/dev-python/dropbox/dropbox-12.1.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 2021-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1
+
+MY_PN=dropbox-sdk-python
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="The offical Dropbox SDK for Python"
+HOMEPAGE="https://www.dropbox.com/developers"
+# pypi does not have tests, stick with gh
+SRC_URI="https://github.com/dropbox/${MY_PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/requests-2.16.2[${PYTHON_USEDEP}]
+	>=dev-python/six-1.12.0[${PYTHON_USEDEP}]
+	dev-python/stone[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+"
+
+# disable tests that need SCOPED_USER_DROPBOX_TOKEN
+# and tests that fail
+EPYTEST_DESELECT=(
+	test/integration/test_dropbox.py
+	test/unit/test_dropbox_unit.py::TestClient
+	test/unit/test_dropbox_unit.py::TestOAuth::test_NoRedirect_whole_flow
+)
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	if [[ ${PV} == *_p* ]] ; then
+		local MY_PV=$(ver_cut 1-3)
+
+		sed -i -e "s/__version__ = '0.0.0'/__version__ = '${MY_PV}'/" dropbox/dropbox_client.py || die
+	fi
+
+	sed -i -e "s/^import mock$/from unittest import mock/" test/unit/test_dropbox_unit.py || die
+
+	distutils-r1_src_prepare
+}