dev-python/zope-testrunner: add 6.2.1

Signed-off-by: Julien Roy <julien@jroy.ca>

dev-python/zope-testrunner/Manifest

@@ -1 +1,2 @@
+DIST zope.testrunner-6.2.1.tar.gz 150397 BLAKE2B 57210c321ae66738cc2c533a3e9d183273bbc2b98b639fa3a30502ddcb98154eb62f36d50d25674b255547788433498f341ceaec9c1744810571df007632bffd SHA512 5dc8764a518b49f42ef16b64ccb70fb772de0ccda2057ae90597a64975b01c25e885133385e791376f6664b72c67a98499934ebda64238511beef28416ec6add
 DIST zope.testrunner-6.2.tar.gz 150192 BLAKE2B 4ce0a5ed134910a4fb8cbc68700fbcd3d6e7508654e1ac68d51f5671e797e886a28ef0b55126f5b359cb704ec4b1c4d6f1ed9e66d25d0f83dd62e4884a262358 SHA512 5fc559c497c9db67c81af692e83d60d5cb75ee4cdb28b25c23040eccdaf01d704b2897b385e35e09e916792f6bf7155eded67d4b5de3c1beb1a435590c249dfd

dev-python/zope-testrunner/zope-testrunner-6.2.1.ebuild

@@ -0,0 +1,54 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+PYPI_NO_NORMALIZE=1
+PYPI_PN="${PN/-/\.}"
+inherit distutils-r1 pypi
+
+DESCRIPTION="This package provides a flexible test runner with layer support."
+HOMEPAGE="https://github.com/zopefoundation/zope.testrunner
+	https://pypi.org/project/zope.testrunner/
+"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/zope-interface[${PYTHON_USEDEP}]
+	dev-python/zope-exceptions[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinxcontrib-programoutput[${PYTHON_USEDEP}] )
+	test? ( dev-python/zope-testing[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+
+distutils_enable_sphinx docs
+distutils_enable_tests unittest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "/'setuptools'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	distutils_write_namespace zope
+	eunittest
+}
+
+python_install() {
+	# Do not install unit tests
+	rm -r "${BUILD_DIR}/install$(python_get_sitedir)/zope/testrunner/tests" || die
+	distutils-r1_python_install
+}