From 37c0464053d64e6ae341538f33fd943214dfd6fc Mon Sep 17 00:00:00 2001
From: "Haelwenn (lanodan) Monnier" <contact@hacktivis.me>
Date: Sat, 12 Jul 2025 04:08:59 +0200
Subject: [PATCH] dev-util/deblob: add 0.11

Signed-off-by: Haelwenn (lanodan) Monnier <contact@hacktivis.me>
---
 dev-util/deblob/Manifest           |  2 +
 dev-util/deblob/deblob-0.11.ebuild | 72 ++++++++++++++++++++++++++++++
 dev-util/deblob/deblob-9999.ebuild | 14 +++---
 3 files changed, 82 insertions(+), 6 deletions(-)
 create mode 100644 dev-util/deblob/deblob-0.11.ebuild

diff --git a/dev-util/deblob/Manifest b/dev-util/deblob/Manifest
index 6911cdab2b..84a43b5541 100644
--- a/dev-util/deblob/Manifest
+++ b/dev-util/deblob/Manifest
@@ -1,4 +1,6 @@
 DIST deblob-0.10.tar.gz 9015 BLAKE2B f7776e6a939116f9f0836d3204c9a6ddab34433dd2b609cc0ad5eb3581682e534980baf586aac22e65e5e85af455602d4d93ca461025a68560ede62ea867af75 SHA512 879fb822f4dec357e99a2d5db61608362735018b59aa4aee1f952f6525769667149f0c406862e6b542184c74efc261db75408469d6c1c70ff18a086878658dd6
 DIST deblob-0.10.tar.gz.sign 141 BLAKE2B 03256b22f17b8c88d9f6ef95591156e2c7904b8fadc97b2163379000a526106f56908da6d3cbb19a8ea5a97566bcbf1a7fab3cfb1f13fbabbd699d57cba2d0ba SHA512 ceb3fc5a1021686e287fd95602ae78cb616c53e3945f6eea9d56a8ebff49d5ff37634a6b4cda5487140514ec3dd864e88bbb5d98007f4421e2e2a04aa9f6d139
+DIST deblob-0.11.tar.gz 9044 BLAKE2B e16bcc5bf44d0cc6d35cb763b6eb949c6620cd97bd0fda93aa29d2777243bca0ebbfc54c28531b50906f198dea3bf448228aa457053c0ae9e97f7c51b00ebb11 SHA512 c3aa2fdaf72fd8a1b5e4b07cca8462ab917ee5b01447234e862acc7810a98c7dc5427108970059a5c07059020f6dff2e71301debbf14c9347857e03a2ec2de7e
+DIST deblob-0.11.tar.gz.sign 141 BLAKE2B ff5faac3334d791beecbec919c7d65281b17c4effb017811be9706a50fb1c67f85ac5825a9f8c04bd89ded748d87f5e87b80840d0b76365183d6e7602f5350f9 SHA512 5cd517dc6ed5eb002a67bcee8161dd21554304abedfc3e42f1d8e5ccb7bd5db718ae11ccdb525d5170a8e599249d5bb6ab6fd22d916ab75011b5f83bd8c90a22
 DIST deblob-test-0.10.tar.gz 2054850 BLAKE2B e4420fdf7076bde62c431862397ee0deeb0a6b79a8f8f4e51b88a1b5b7e23390629c05c2f54b77a2263c22146bf6cb8ed18c51cc01cb9576d29f1f4126699d96 SHA512 bdd5cb4998ae5c0bc39a903f5cbf0f93783d590e8d4a397442aa78a50605cd39a5c6195623706445b7a24e938c9f4861138a75f935924c0930ff3f82bb511443
 DIST deblob-test-0.10.tar.gz.sign 141 BLAKE2B fc4121172a0cff87cf264097813b52ee4a4f5334bcab09756cbc9aef4b335beed31fb9f44ecd6269231783b0e9ad3de2e8c2fac543ff7158f0f9be55ff9e6008 SHA512 c51f8aa9f403ede2288cb64a9433eecb657f357fefe810fc813ee8d3e7bdd37fe0d3dff0f5fd6239ab1a496f0dc1402406d7c052a746e1004ca9a75aefb09a6b
diff --git a/dev-util/deblob/deblob-0.11.ebuild b/dev-util/deblob/deblob-0.11.ebuild
new file mode 100644
index 0000000000..625ee85fea
--- /dev/null
+++ b/dev-util/deblob/deblob-0.11.ebuild
@@ -0,0 +1,72 @@
+# Copyright 2021-2025 Haelwenn (lanodan) Monnier <contact@hacktivis.me>
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_TEST_V="0.10"
+
+if [[ "$PV" == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.hacktivis.me/git/deblob.git"
+else
+	VERIFY_SIG_METHOD=signify
+	inherit verify-sig
+
+	SRC_URI="
+		https://distfiles.hacktivis.me/releases/deblob/${P}.tar.gz
+		test? ( https://distfiles.hacktivis.me/releases/deblob-test/deblob-test-${MY_TEST_V}.tar.gz )
+		verify-sig? (
+			https://distfiles.hacktivis.me/releases/deblob/${P}.tar.gz.sign
+			test? ( https://distfiles.hacktivis.me/releases/deblob-test/deblob-test-${MY_TEST_V}.tar.gz.sign )
+		)
+	"
+	KEYWORDS="~amd64 ~arm64 ~riscv"
+fi
+
+DESCRIPTION="remove binary executables from a directory"
+# permalink
+HOMEPAGE="https://hacktivis.me/projects/deblob"
+LICENSE="BSD"
+SLOT="0"
+
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-lang/hare-0.25.2:=
+	>=dev-hare/hare-json-0.25.2.0
+"
+
+# built by hare
+QA_FLAGS_IGNORED="usr/bin/deblob"
+
+if [[ "${PV}" != "9999" ]]
+then
+	BDEPEND="${BDEPEND} verify-sig? ( sec-keys/signify-keys-lanodan:2025 )"
+
+	VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/signify-keys/signify-keys-lanodan-2025.pub"
+
+	src_unpack() {
+		if use verify-sig; then
+			# Too many levels of symbolic links
+			cd "${DISTDIR}" || die
+			cp ${A} "${WORKDIR}" || die
+			cd "${WORKDIR}" || die
+
+			verify-sig_verify_detached "${P}.tar.gz" "${P}.tar.gz.sign"
+			use test && verify-sig_verify_detached "deblob-test-${MY_TEST_V}.tar.gz" "deblob-test-${MY_TEST_V}.tar.gz.sign"
+		fi
+
+		default
+
+		if use test; then
+			rm -r "${WORKDIR}/${P}/test" || die
+			mv "${WORKDIR}/deblob-test-${MY_TEST_V}" "${WORKDIR}/${P}/test" || die
+		fi
+	}
+fi
+
+src_install() {
+	PREFIX="/usr" default
+}
diff --git a/dev-util/deblob/deblob-9999.ebuild b/dev-util/deblob/deblob-9999.ebuild
index b47bdbc3ac..625ee85fea 100644
--- a/dev-util/deblob/deblob-9999.ebuild
+++ b/dev-util/deblob/deblob-9999.ebuild
@@ -3,6 +3,8 @@
 
 EAPI=8
 
+MY_TEST_V="0.10"
+
 if [[ "$PV" == 9999 ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://anongit.hacktivis.me/git/deblob.git"
@@ -12,10 +14,10 @@ else
 
 	SRC_URI="
 		https://distfiles.hacktivis.me/releases/deblob/${P}.tar.gz
-		test? ( https://distfiles.hacktivis.me/releases/deblob-test/deblob-test-${PV}.tar.gz )
+		test? ( https://distfiles.hacktivis.me/releases/deblob-test/deblob-test-${MY_TEST_V}.tar.gz )
 		verify-sig? (
 			https://distfiles.hacktivis.me/releases/deblob/${P}.tar.gz.sign
-			test? ( https://distfiles.hacktivis.me/releases/deblob-test/deblob-test-${PV}.tar.gz.sign )
+			test? ( https://distfiles.hacktivis.me/releases/deblob-test/deblob-test-${MY_TEST_V}.tar.gz.sign )
 		)
 	"
 	KEYWORDS="~amd64 ~arm64 ~riscv"
@@ -32,8 +34,8 @@ IUSE="test"
 RESTRICT="!test? ( test )"
 
 DEPEND="
-	>=dev-lang/hare-0.24.2:=
-	dev-hare/hare-json
+	>=dev-lang/hare-0.25.2:=
+	>=dev-hare/hare-json-0.25.2.0
 "
 
 # built by hare
@@ -53,14 +55,14 @@ then
 			cd "${WORKDIR}" || die
 
 			verify-sig_verify_detached "${P}.tar.gz" "${P}.tar.gz.sign"
-			use test && verify-sig_verify_detached "deblob-test-${PV}.tar.gz" "deblob-test-${PV}.tar.gz.sign"
+			use test && verify-sig_verify_detached "deblob-test-${MY_TEST_V}.tar.gz" "deblob-test-${MY_TEST_V}.tar.gz.sign"
 		fi
 
 		default
 
 		if use test; then
 			rm -r "${WORKDIR}/${P}/test" || die
-			mv "${WORKDIR}/deblob-test-${PV}" "${WORKDIR}/${P}/test" || die
+			mv "${WORKDIR}/deblob-test-${MY_TEST_V}" "${WORKDIR}/${P}/test" || die
 		fi
 	}
 fi