diff --git a/dev-python/pdm/Manifest b/dev-python/pdm/Manifest
new file mode 100644
index 0000000000..1e98cd1572
--- /dev/null
+++ b/dev-python/pdm/Manifest
@@ -0,0 +1 @@
+DIST pdm-2.4.9.tar.gz 2883026 BLAKE2B f9b481562d257f54f67d768cb40d6371f97a38880cc4f30e2a8615bdc75baf050301df97ed95c66c2553919d36cac5111b7d8c0efad362e97925fc8064a876fb SHA512 1a8952c99e408c7a37d3f3f1e3655cfbe8674e323a21501cdfe7740580ddb8b854b69c9bec46d091027fe16a310929f58e43c26d28e10a5d0f3a81c356edd1fe
diff --git a/dev-python/pdm/metadata.xml b/dev-python/pdm/metadata.xml
new file mode 100644
index 0000000000..16e052a257
--- /dev/null
+++ b/dev-python/pdm/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>falbrechtskirchinger@gmail.com</email>
+    <name>Florian Albrechtskirchinger</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="pypi">pdm</remote-id>
+    <remote-id type="github">pdm-project/pdm</remote-id>
+  </upstream>
+</pkgmetadata>
diff --git a/dev-python/pdm/pdm-2.4.9.ebuild b/dev-python/pdm/pdm-2.4.9.ebuild
new file mode 100644
index 0000000000..c5f0fc5448
--- /dev/null
+++ b/dev-python/pdm/pdm-2.4.9.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm
+PYTHON_COMPAT=( python3_{10..11} pypy3 )
+
+inherit bash-completion-r1 distutils-r1 pypi
+
+DESCRIPTION="Modern Python package and dependency manager supporting latest PEP standards"
+HOMEPAGE="
+	https://github.com/pdm-project/pdm/
+	https://pypi.org/project/pdm/
+"
+
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+
+RDEPEND="
+	dev-python/blinker[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+	dev-python/requests-toolbelt[${PYTHON_USEDEP}]
+	dev-python/unearth[${PYTHON_USEDEP}]
+	dev-python/findpython[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+	dev-python/shellingham[${PYTHON_USEDEP}]
+	dev-python/python-dotenv[${PYTHON_USEDEP}]
+	<dev-python/resolvelib-1.0.0[${PYTHON_USEDEP}]
+	dev-python/installer[${PYTHON_USEDEP}]
+	dev-python/cachecontrol[${PYTHON_USEDEP}]
+
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_compile_all() {
+	PDM_CHECK_UPDATE=0 "${EPYTHON}" -m pdm completion bash > completion.bash || die
+	PDM_CHECK_UPDATE=0 "${EPYTHON}" -m pdm completion zsh > completion.zsh || die
+}
+
+python_test() {
+	epytest -m "not network"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newbashcomp completion.bash pdm
+
+	insinto /usr/share/zsh/site-functions
+	newins completion.zsh _pdm
+}