diff --git a/www-misc/gitea2rss/Manifest b/www-misc/gitea2rss/Manifest
new file mode 100644
index 0000000000..f924f06f91
--- /dev/null
+++ b/www-misc/gitea2rss/Manifest
@@ -0,0 +1 @@
+DIST gitea2rss-0.7.0.tar.gz 25135 BLAKE2B f39e59aaa1381155ba1ec9c7bf831120a3c1504458515854d66e38cdc5d76bd436aeb055c85136c7010b22a65e87482d604f3542a6cf9f00cf9b6a906afa8cfc SHA512 1041897d3e1cbe60f75330403abf27b990923f2f47ea5c9d513dcf50a4e92a457ab2989067e4d29b8bbe16b4be39fdb74e87b337f49825607831c5e4090a0a80
diff --git a/www-misc/gitea2rss/gitea2rss-0.7.0.ebuild b/www-misc/gitea2rss/gitea2rss-0.7.0.ebuild
new file mode 100644
index 0000000000..a50a8f05dc
--- /dev/null
+++ b/www-misc/gitea2rss/gitea2rss-0.7.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+fi
+
+DESCRIPTION="Generates RSS feeds from Gitea releases, tags and commits"
+HOMEPAGE="https://schlomp.space/tastytea/gitea2rss"
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://schlomp.space/tastytea/gitea2rss.git"
+else
+	SRC_URI="https://schlomp.space/tastytea/gitea2rss/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+if [[ "${PV}" != "9999" ]]; then
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+IUSE="test"
+
+RDEPEND="
+	net-misc/curl[ssl]
+	dev-libs/jsoncpp
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-cpp/catch )
+"
+BDEPEND="
+	virtual/pkgconfig
+	app-text/asciidoc
+"
+
+RESTRICT="!test? ( test )"
+
+DOCS=("README.adoc" "doc/nginx-example.conf")
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_TESTS="$(usex test)"
+	)
+	if use test; then
+		# Don't run tests that need a network connection.
+		mycmakeargs+=(-DEXTRA_TEST_ARGS="~[http]")
+	fi
+
+	cmake_src_configure
+}
+
+src_test() {
+	BUILD_DIR="${BUILD_DIR}/tests" cmake_src_test
+}
diff --git a/www-misc/gitea2rss/metadata.xml b/www-misc/gitea2rss/metadata.xml
new file mode 100644
index 0000000000..3b365639d8
--- /dev/null
+++ b/www-misc/gitea2rss/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>gentoo@tastytea.de</email>
+    <name>Ronny (tastytea) Gutbrod</name>
+  </maintainer>
+  <upstream>
+    <bugs-to>https://schlomp.space/tastytea/gitea2rss/issues</bugs-to>
+  </upstream>
+</pkgmetadata>