net-mail/dovecot-fts-xapian: initial ebuild (1.5.2)

Xapian is a Dovecot plugin that offers Full Text Search capabilities
without a ton of dependencies.

* Add dovecot-fts-xapian-1.5.2

Signed-off-by: Philippe Chaintreuil <gentoo_bugs_peep@parallaxshift.com>

net-mail/dovecot-fts-xapian/Manifest

@@ -0,0 +1 @@
+DIST dovecot-fts-xapian-1.5.2.tar.gz 2985120 BLAKE2B 25ab535a93bbc6c0ce6c50cf01916b3349c7a34d9746ea1f87e1bf45eaa643370a3f6a5e967a168b29d0bd601f3dddbff43dd75eab64f4d62d5277f78374cf9f SHA512 afbdd9866d61104d22875eb326a2a893ef0b252e6a493c939db8a29f2d7460a70c8e7648729840ea89d60c374ce75bb34a9c90e7ca2d9c4a9239fa3b2f5905a4

net-mail/dovecot-fts-xapian/dovecot-fts-xapian-1.5.2.ebuild

@@ -0,0 +1,42 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Dovecot FTS plugin backed by Xapian"
+HOMEPAGE="https://github.com/grosjo/fts-xapian"
+SRC_URI="https://github.com/grosjo/fts-xapian/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="static-libs"
+
+RDEPEND="
+	dev-libs/icu:=
+	>=dev-libs/xapian-1.4:=
+	net-mail/dovecot:=
+	"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/fts-xapian-${PV}"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-dovecot="${EPREFIX}/usr/$(get_libdir)/dovecot" \
+		$( use_enable static-libs static )
+}
+
+src_install() {
+	default
+	use static-libs || find "${ED}" -name '*.la' -delete
+}

net-mail/dovecot-fts-xapian/metadata.xml

@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>git_peep@parallaxshift.com</email>
+		<name>Philippe 'Peep' Chaintreuil</name>
+	</maintainer>
+	<upstream>
+		<maintainer>
+			<name>Joan Moreau</name>
+			<email>jom@grosjo.net</email>
+		</maintainer>
+		<remote-id type="github">grosjo/fts-xapian</remote-id>
+		<changelog>https://github.com/grosjo/fts-xapian/releases</changelog>
+		<bugs-to>https://github.com/grosjo/fts-xapian/issues/new</bugs-to>
+	</upstream>
+</pkgmetadata>