dev-util/google-antigravity: add 2.21.1

Signed-off-by: Florian Albrechtskirchinger <falbrechtskirchinger@gmail.com>

dev-util/google-antigravity/Manifest

@@ -4,3 +4,5 @@ DIST google-antigravity-2.19.1_amd64.tar.gz 179969257 BLAKE2B c7fd57fec5962f988e
 DIST google-antigravity-2.19.1_arm64.tar.gz 177868636 BLAKE2B 41f197084161143a7022a22846004a025d67f5363ae78e9348152dcfbc51bf8bdbe6a4f9dc172bf44456dd2a804e3bd374bf678ab3a449a666324efcc9c674ce SHA512 17639392266ce8da6a29e9f0aebd9522b5c335a4c292cc12074e61b295a5b3af3b71f9b8378ace8d02caf5759defe36b3b7d060e13e3182e413899667ddb1979
 DIST google-antigravity-2.21.0_amd64.tar.gz 180481306 BLAKE2B 35b4b3d55c5baf37867391f44eec494a61809b8cbfe7b5dedd0db1277be768525caae87d6597ac70ea398fea1fca29e6bb5a506af66ffe5974628f9aae696f20 SHA512 3a406e3d8dea8bbc71d8205f8da89aa5376a1c6b5b133b57fdaa09abf09b6f032011174aa2715b12c769ab25b04337faba65abd7ba37851f7ae09b77fbe00ddb
 DIST google-antigravity-2.21.0_arm64.tar.gz 178357645 BLAKE2B d6e732bb3936d5599348de183c3553a9a36131a0f3b99ebdd5bbd02451300309dd9748b624f68feb7785943fe05aa3ee7371f027783257699912e1734400c28d SHA512 4362ae23d881e678672147b7393af7a28bcc7388ff97f1d4ec53babc1a19d225d1cf52077aca88b5b6846a5c271b1b01cd19be21b7585c94ce02548e457d06ba
+DIST google-antigravity-2.21.1_amd64.tar.gz 180481397 BLAKE2B dd19e82862f64e5f4781c462b810c971d012894b2500435da42244ef87f6263eef77adfaf78aaecefbd810406182540c6fd084395f215afb867e989e6dd9f157 SHA512 f873f074e17d961b7d45a3cd19447d59d76b2e4fc5f4066773c728ab8fad1747fca072bba9a148b3cfc222b595a3409d2d419f7ecfe7b2f06f7aadb5f793a93e
+DIST google-antigravity-2.21.1_arm64.tar.gz 178357974 BLAKE2B 668c39ee4aa18423640a2bb424fc27ebb4d1dccb462072fae83c981d25c95ac8af14c3cfaa8f5574ddd5a8f06f165a39ccfe743c0563d00682f7ea3124c138b2 SHA512 edcfa12a7c856a1b06a80e6b0f47396054b9252b0ac5c5d0ec3ef385c30593b09ffed279d7cb7316b95a042a2cce463f85b848641c347771d5f5eac836136e3a

dev-util/google-antigravity/google-antigravity-2.21.1.ebuild

@@ -0,0 +1,115 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="af am ar bg bn ca cs da de el en-GB en-US es-419 es et fa fi
+		fil fr gu he hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt-BR
+		pt-PT ro ru sk sl sr sv sw ta te th tr uk ur vi zh-CN zh-TW"
+
+inherit chromium-2 desktop optfeature pax-utils xdg
+
+EXECUTION_ID="5614635819335680"
+
+MY_PN="${PN#google-}"
+DESCRIPTION="Google Antigravity 2.0, a dedicated platform to work with agents"
+HOMEPAGE="https://antigravity.google/"
+BASE_URI="https://storage.googleapis.com/antigravity-public/antigravity-hub/${PV}-${EXECUTION_ID}"
+SRC_URI="
+	amd64? ( ${BASE_URI}/linux-x64/Antigravity.tar.gz -> ${P}_amd64.tar.gz )
+	arm64? ( ${BASE_URI}/linux-arm/Antigravity.tar.gz -> ${P}_arm64.tar.gz )
+"
+S="${WORKDIR}"
+
+# It's complicated...
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~arm64"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	|| (
+		sys-apps/systemd
+		sys-apps/systemd-utils
+	)
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-crypt/libsecret[crypt]
+	app-misc/ca-certificates
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/libglvnd
+	media-libs/mesa
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	virtual/zlib:=
+	sys-process/lsof
+	x11-libs/cairo
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libxkbcommon
+	x11-libs/libxkbfile
+	x11-libs/libXrandr
+	x11-libs/libXScrnSaver
+	x11-libs/pango
+	x11-misc/xdg-utils
+"
+
+QA_PREBUILT="*"
+QA_DESKTOP_FILE="usr/share/applications/${MY_PN}.*\\.desktop"
+
+AGY_HOME_BASE="opt/google"
+AGY_HOME="${AGY_HOME_BASE}/${MY_PN}"
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	default
+	mv "Antigravity-"* "${MY_PN}" || die
+}
+
+src_prepare() {
+	default
+
+	cd "${MY_PN}" || die
+
+	pushd locales > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+}
+
+src_install() {
+	cd "${MY_PN}" || die
+
+	mkdir -p "${ED}/${AGY_HOME}" || die
+	cp -r . "${ED}/${AGY_HOME}" || die
+
+	pax-mark m "${ED}/${AGY_HOME}/${MY_PN}"
+	fperms 0755 "/${AGY_HOME}/${MY_PN}"
+	dosym "/${AGY_HOME}/${MY_PN}" "/usr/bin/${MY_PN}"
+
+	fperms 4711 "/${AGY_HOME}/chrome-sandbox"
+
+	domenu "${FILESDIR}/${MY_PN}.desktop"
+	newicon -s scalable "${FILESDIR}/${MY_PN}.png" ${MY_PN}.png
+
+	insinto /usr/share/metainfo
+	doins "${FILESDIR}/${MY_PN}.metainfo.xml"
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "desktop notifications" x11-libs/libnotify
+}