dev-python/hunter: add 3.6.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-python/hunter/Manifest

@@ -1 +1,2 @@
 DIST hunter-3.5.1.gh.tar.gz 543137 BLAKE2B a06966f78fd442231c08e2aafe57702f7cc16e5db6aa9a1da7288e4a3a05ff9db3dfc49352641610ade31cb967996c3add64f07ddf637f46e5d269e9d0363a9f SHA512 2c302fa8b88c07be5361f11d8c250c5673be9dc691df9e966959eed45eaf0a8499ae8a6381256d83ab7219c818ed981628fb3299ef5d17d7b1d95c43a2fc63a7
+DIST hunter-3.6.0.gh.tar.gz 626304 BLAKE2B 8cef43f6427863724b6a7f848ee938011b8de2100c12c4f7cd049156733da0076f3d04d74328aeff06edeab6e5d85a9dd564b6281644a1e6172741573f066127 SHA512 5b5a6e7e2f26f71ff151d40fe0b660141ff2d2637fa9a226e9a1a4ead5267cf1e851baa0a439a94aa4b537db3fbdc5cd660304f64ad08ee90a115516c3848547

dev-python/hunter/hunter-3.6.0.ebuild

@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=standalone
+DISTUTILS_EXT=1
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Hunter is a flexible code tracing toolkit"
+HOMEPAGE="
+	https://github.com/ionelmc/python-hunter
+	https://pypi.org/project/hunter/
+"
+SRC_URI="https://github.com/ionelmc/python-${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/python-${P}"
+TEST_S="${S}_test"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/aspectlib[${PYTHON_USEDEP}]
+		dev-python/ipdb[${PYTHON_USEDEP}]
+		dev-python/manhole[${PYTHON_USEDEP}]
+		dev-python/process-tests[${PYTHON_USEDEP}]
+		dev-python/pytest-benchmark[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+		sys-devel/gdb
+	)
+"
+
+DOCS=( AUTHORS.rst CHANGELOG.rst README.rst )
+
+EPYTEST_DESELECT=(
+	# broken
+	#tests/test_tracer.py::test_source_cython
+	tests/test_tracer.py::test_fullsource_cython
+
+	# flaky
+	tests/test_remote.py
+)
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+	">=dev-python/sphinx-py3doc-enhanced-theme-2.3.2"
+
+src_unpack() {
+	default
+
+	if use test; then
+		cp -a "${S}" "${TEST_S}" || die
+		mv -f "${TEST_S}"/tests/setup.py "${TEST_S}"/setup.py || die
+	fi
+}
+
+src_prepare() {
+	default
+	find . -name '*.c' -delete || die "removing csources failed"
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	if use test; then
+		einfo "  Building tests"
+		cd "${TEST_S}" || die
+		esetup.py build_ext -j $(makeopts_jobs) --inplace
+	fi
+}
+
+python_test() {
+	cd "${TEST_S}"/tests || die
+	epytest
+}