diff --git a/dev-cpp/xtl/Manifest b/dev-cpp/xtl/Manifest
index 8820db2e31..f0e37e407d 100644
--- a/dev-cpp/xtl/Manifest
+++ b/dev-cpp/xtl/Manifest
@@ -1 +1,2 @@
 DIST xtl-0.7.5.tar.gz 160548 BLAKE2B 61d8c8c8e69722e2d29bd70991840650b22f2f440e2ee8100786869e4410ace8a5063cc0101361aedca963607cf046bb46e923fc096e25d731affdf2876ef4fa SHA512 fb447334f68f255d7d28c9202eee2cec70d007c1031f3756a6acd0cc019c0d95ed1d12ec63f2e9fb3df184f9ec305e6a3c808bb88c1e3eb922916ad059d2e856
+DIST xtl-0.8.0.tar.gz 138356 BLAKE2B 18a06781dff9706807b9f91d0c6dd921eff3258ac6c9d28710b758dee5f1e72aef2cba1ddb3b8a9158f340e9326ab67b9bedecef0eafaa9f6168ba873814b589 SHA512 534d7e3779a8b95371994bed16ddab00083e3a068244354d59aabd4576b7e0678c92064e0a93bba94ed3195410e3b8aefdec9e8c53d70c7d9e83d318377f522a
diff --git a/dev-cpp/xtl/xtl-0.8.0.ebuild b/dev-cpp/xtl/xtl-0.8.0.ebuild
new file mode 100644
index 0000000000..d9e2128f7d
--- /dev/null
+++ b/dev-cpp/xtl/xtl-0.8.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit cmake python-any-r1
+
+DESCRIPTION="Algorithms and containers used by the xtensor stack and the xeus stack"
+HOMEPAGE="https://github.com/xtensor-stack/xtl"
+SRC_URI="https://codeload.github.com/xtensor-stack/${PN}/tar.gz/refs/tags/${PV} -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="doc test"
+
+BDEPEND="
+	doc? (
+		app-text/doxygen
+		$(python_gen_any_dep '
+			dev-python/breathe[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+		')
+	)
+	test? ( dev-cpp/doctest )
+"
+
+RESTRICT="!test? ( test )"
+
+python_check_deps() {
+	python_has_version \
+		"dev-python/breathe[${PYTHON_USEDEP}]" \
+		"dev-python/sphinx[${PYTHON_USEDEP}]" \
+		"dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=( -DBUILD_TESTS=$(usex test) )
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && emake -C docs html
+}
+
+src_install() {
+	use doc && HTML_DOCS=( docs/build/html/* )
+	cmake_src_install
+}