From 2f5f9cac8da2afc6cd5155e3a288ee7008445af5 Mon Sep 17 00:00:00 2001
From: Alexander Puck Neuwirth <alexander@neuwirth-informatik.de>
Date: Thu, 6 Mar 2025 14:12:08 +0100
Subject: [PATCH] net-im/zulip-desktop-bin: new package, add 5.11.1

Signed-off-by: Alexander Puck Neuwirth <alexander@neuwirth-informatik.de>
Closes: https://github.com/gentoo/guru/pull/300
---
 net-im/zulip-desktop-bin/Manifest             |  1 +
 net-im/zulip-desktop-bin/metadata.xml         | 11 +++
 .../zulip-desktop-bin-5.11.1.ebuild           | 99 +++++++++++++++++++
 3 files changed, 111 insertions(+)
 create mode 100644 net-im/zulip-desktop-bin/Manifest
 create mode 100644 net-im/zulip-desktop-bin/metadata.xml
 create mode 100644 net-im/zulip-desktop-bin/zulip-desktop-bin-5.11.1.ebuild

diff --git a/net-im/zulip-desktop-bin/Manifest b/net-im/zulip-desktop-bin/Manifest
new file mode 100644
index 0000000000..f9a4cd5618
--- /dev/null
+++ b/net-im/zulip-desktop-bin/Manifest
@@ -0,0 +1 @@
+DIST Zulip-5.11.1-amd64.deb 77340186 BLAKE2B 11ec4a710c968341dd6591966e2edec925f2a825059d61cc2453866a79cfad635862cad70c91b6a2637e74379ced318fc8fa92c094967d048f780b9e2c586cef SHA512 2fbb49606dfd9c147817427e510781526e9cce3f244f9ecf9f86cf37f6cd73f4029412fbed2c70a9286613873a1c72cf1ba5b63f1947f077b9a19a128c632e46
diff --git a/net-im/zulip-desktop-bin/metadata.xml b/net-im/zulip-desktop-bin/metadata.xml
new file mode 100644
index 0000000000..b2fc6f1123
--- /dev/null
+++ b/net-im/zulip-desktop-bin/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>alexander@neuwirth-informatik.de</email>
+		<name>Alexander Puck Neuwirth</name>
+	</maintainer>
+	<longdescription>
+		Zulip is an open-source team collaboration tool with unique topic-based threading that combines the best of email and chat to make remote work productive and delightful.
+	</longdescription>
+</pkgmetadata>
diff --git a/net-im/zulip-desktop-bin/zulip-desktop-bin-5.11.1.ebuild b/net-im/zulip-desktop-bin/zulip-desktop-bin-5.11.1.ebuild
new file mode 100644
index 0000000000..46f80ae785
--- /dev/null
+++ b/net-im/zulip-desktop-bin/zulip-desktop-bin-5.11.1.ebuild
@@ -0,0 +1,99 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="
+	af am ar bg bn ca cs da de el en-GB en-US es es-419 et fa fi fil fr gu he hi
+	hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt-BR pt-PT ro ru sk sl sr sv
+	sw ta te th tr uk ur vi zh-CN zh-TW
+"
+
+inherit chromium-2 desktop unpacker xdg
+
+DESCRIPTION="Organized chat for distributed teams."
+HOMEPAGE="https://zulip.com/"
+SRC_URI="
+	amd64? ( https://download.zulip.com/desktop/apt/pool/main/z/zulip/Zulip-5.11.1-amd64.deb )
+"
+
+S="${WORKDIR}"
+
+LICENSE="
+	MIT BSD BSD-2 BSD-4 AFL-2.1 Apache-2.0 Ms-PL GPL-2 LGPL-2.1 APSL-2
+	unRAR OFL-1.1 CC-BY-SA-3.0 MPL-2.0 android public-domain all-rights-reserved
+"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+
+RESTRICT="bindist mirror"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libxkbcommon
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="opt/Zulip/*"
+
+pkg_pretend() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_prepare() {
+	default
+	# cleanup languages
+	pushd "opt/Zulip/locales" || die
+	chromium_remove_language_paks
+	popd || die
+}
+
+src_configure() {
+	chromium_suid_sandbox_check_kernel_config
+	default
+}
+
+src_install() {
+	for size in {16,32,64,128,512,1024}; do
+		doicon -s ${size} "usr/share/icons/hicolor/${size}x${size}/apps/zulip.png"
+	done
+
+	domenu usr/share/applications/zulip.desktop
+
+	local DESTDIR="/opt/Zulip"
+	pushd "opt/Zulip" || die
+
+	exeinto "${DESTDIR}"
+	doexe chrome-sandbox chrome_crashpad_handler zulip *.so*
+
+	insinto "${DESTDIR}"
+	doins *.pak *.bin *.json *.dat
+	insopts -m0755
+	doins -r locales resources
+
+	# Chrome-sandbox requires the setuid bit to be specifically set.
+	# see https://github.com/electron/electron/issues/17972
+	fperms 4755 "${DESTDIR}"/chrome-sandbox
+
+	dosym "${DESTDIR}"/zulip /opt/bin/zulip
+	popd || die
+}