net-im/nheko: add 0.11.0

Signed-off-by: Ronny (tastytea) Gutbrod <gentoo@tastytea.de>

net-im/nheko/Manifest

@@ -1 +1,2 @@
 DIST nheko-0.10.2.tar.gz 1608905 BLAKE2B 10b7b7d1f3e7525ae5ec4b78af228382440c5c64a3716b530506346372856035435d6e2d4e1724f2580ee384852ab0dd4e4b728eed92df827dc5cb3f2853b30b SHA512 b00c45115ab52f9cce5958aa594f6d316bdb917004e284d28ba3003c815bdc532ff1e7bbd5e542bb89a43fd552af3fa44b70ce66eb26b0bcff65beaea1f6b3cd
+DIST nheko-0.11.0.tar.gz 1752073 BLAKE2B 01a26449c6bef6d46535973e09455dd13c9208d7104ddeb803082c06fb63e38db5c9fdd8a2300ee0821c7a2f74a36834371a01dacaa21f64b79a992fd2193e7e SHA512 23d1c9fc1defe869e4e8b1f46f12d2ce377b3752166b94a9cecf11aad5fb9ce3db96f593f4f2ce56e6dc8bf24885fa618dbb799b86e8b5e390ba20356efa0bf3

net-im/nheko/nheko-0.11.0.ebuild

@@ -0,0 +1,90 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake optfeature xdg
+
+DESCRIPTION="Native desktop client for Matrix using Qt"
+HOMEPAGE="https://github.com/Nheko-Reborn/nheko"
+SRC_URI="https://github.com/Nheko-Reborn/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="X video voip"
+REQUIRED_USE="video? ( voip )"
+
+MY_GST_V="1.18"
+RDEPEND="
+	app-text/cmark:=
+	dev-cpp/qt-jdenticon
+	dev-db/lmdb:=
+	>=dev-db/lmdb++-1.0.0
+	dev-libs/libfmt:=
+	>=dev-libs/mtxclient-0.9.0:=
+	>=dev-libs/qtkeychain-0.12.0:=
+	>=dev-libs/re2-0.2022.04.01:=
+	dev-libs/spdlog:=
+	dev-qt/qtconcurrent:5
+	dev-qt/qtdeclarative:5[widgets]
+	dev-qt/qtgraphicaleffects:5
+	dev-qt/qtgui:5[dbus,jpeg,png]
+	dev-qt/qtimageformats
+	dev-qt/qtmultimedia:5[gstreamer,qml,widgets]
+	dev-qt/qtquickcontrols2:5[widgets]
+	dev-qt/qtsvg:5
+	virtual/notification-daemon
+	voip? (
+		>=media-plugins/gst-plugins-dtls-${MY_GST_V}
+		media-plugins/gst-plugins-libnice
+		>=media-plugins/gst-plugins-meta-${MY_GST_V}[opus]
+		>=media-plugins/gst-plugins-srtp-${MY_GST_V}
+		>=media-plugins/gst-plugins-webrtc-${MY_GST_V}
+		video? (
+			>=media-libs/gst-plugins-base-${MY_GST_V}[opengl]
+			>=media-plugins/gst-plugins-meta-${MY_GST_V}[v4l,vpx]
+			>=media-plugins/gst-plugins-qt5-${MY_GST_V}
+			X? (
+				>=media-plugins/gst-plugins-ximagesrc-${MY_GST_V}
+				x11-libs/libxcb:=
+				x11-libs/xcb-util-wm
+			)
+		)
+	)
+"
+DEPEND="
+	dev-cpp/nlohmann_json
+	${RDEPEND}
+"
+BDEPEND="
+	dev-qt/linguist-tools:5
+	|| (
+		app-text/asciidoc
+		dev-ruby/asciidoctor
+	)
+"
+
+src_configure() {
+	local -a mycmakeargs=(
+		"-DVOIP=$(usex voip)"
+	)
+	if use video && use X; then
+		mycmakeargs+=("-DSCREENSHARE_X11=yes")
+	else
+		mycmakeargs+=("-DSCREENSHARE_X11=no")
+	fi
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	optfeature "audio & video file playback support" \
+		"media-plugins/gst-plugins-meta[ffmpeg]"
+	optfeature "secrets storage support other than kwallet (for example gnome-keyring or keepassxc)" \
+		"dev-libs/qtkeychain[gnome-keyring]"
+	optfeature "additional, less common, image format support" \
+		"kde-frameworks/kimageformats"
+
+	xdg_pkg_postinst
+}