dev-util/rtc-testbench: add 5.5

Signed-off-by: Kurt Kanzenbach <kurt@kmk-computers.de>

dev-util/rtc-testbench/Manifest

@@ -1 +1,2 @@
 DIST rtc-testbench-5.4.tar.gz 2132516 BLAKE2B 43d8c8f14c957da28ad51fb06c07c1dc6f6ca777c3f0b347dacdb0dd41864d53efb60e5d1f945b8204bb4a92a2856a4aa3b451de47d6033783ff43205ff4b29d SHA512 95bfa2b83f0b7e36f48bef69cd78a8994734109802a60dd9b2585634d4158034160ce312cfdf280c59b7fba3038457259be094d9b5b4b39123be3e5806a2b9fa
+DIST rtc-testbench-5.5.tar.gz 2156091 BLAKE2B 46086e5e527155dc3ff8e6686e7a1208c32f9ef2395f3b3b15fea09f3bbe28f20995b794c7ac75b2e630b2c4f24712f6130fecc402c7dfa8d890967655ec66c3 SHA512 cb1bb97aba99047c7507a17b4fbb5bd3c2be22d54858abe835f5aa9b5592f81760e608e12854a1ff5e5084cbafdfb1a387d012bec125428e7c5f71d495b1281b

dev-util/rtc-testbench/rtc-testbench-5.5.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LLVM_COMPAT=( {15..21} )
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit cmake python-single-r1 llvm-r2
+
+DESCRIPTION="RTC Testbench is a set of tools for validating Ethernet networks"
+HOMEPAGE="https://github.com/Linutronix/RTC-Testbench"
+SRC_URI="https://github.com/Linutronix/RTC-Testbench/archive/refs/tags/v${PV}.tar.gz -> ${PN}-${PV}.tar.gz"
+S="${WORKDIR}/RTC-Testbench-${PV}"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc mqtt"
+
+# Generated eBPF files
+QA_PREBUILT="usr/lib*/rtc-testbench/ebpf/*.o"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? (
+		media-gfx/graphviz
+		$(python_gen_cond_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+		')
+	)
+	$(llvm_gen_dep '
+		llvm-core/clang:${LLVM_SLOT}=[llvm_targets_BPF(-)]
+	')
+"
+DEPEND="
+	mqtt? ( app-misc/mosquitto )
+	dev-libs/libyaml
+	dev-libs/libbpf:=
+	dev-libs/openssl:=
+	net-libs/xdp-tools
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	${DEPEND}
+"
+
+pkg_setup() {
+	llvm-r2_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MQTT=$(usex mqtt)
+		-DRX_TIMESTAMP=TRUE
+		-DTX_TIMESTAMP=TRUE
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && emake -C "${S}/Documentation" html
+}
+
+src_install() {
+	cmake_src_install
+	use doc && HTML_DOCS=( "${S}/Documentation/_build/html" )
+}