dev-python/pdm: add 2.7.1

Signed-off-by: Florian Albrechtskirchinger <falbrechtskirchinger@gmail.com>

dev-python/pdm/Manifest

@@ -1,2 +1,3 @@
 DIST pdm-2.5.4.tar.gz 3051088 BLAKE2B 717867fe16bdb02efb41136360afe9d7bd06c1706e30014a0a6f66ee69a676461d86f0efe726d6b2002290fb45c1623e92a7614efd7d15742479187c399afc6a SHA512 0a3d1ae42d1541ce458c77ef2bce41564c000fc599ee596aec25d6153d40723595fd0fa1170d7ece6bf24055670030556582b043505d45484acc99052192c063
 DIST pdm-2.6.1.tar.gz 3056889 BLAKE2B 65a3f8e8badf4bd6da2d801ea38f1e85c1e6ccf204a8c4fb1aa7be31c9093ae8ac93b882a511a00814b4838a479fd7b0cfdcea452198388abfec7cdc00b6b610 SHA512 91d0967f407f1f1e2d23e9b43e268d105ed14ec7772eaa433bf20912fa710478ee7a33d01691d795b875cf6385d61bb3d431d176d53c16d3018670e28794b9c5
+DIST pdm-2.7.1.tar.gz 3060384 BLAKE2B b8d848099cf9a72dab98546422ef9aaec32841b73086923817d0da9d7218856f49a21b189134161269f4dc13025fd7b42c577a5f4ca502750cd9b584255622f2 SHA512 51eadc7f8b026cdecdfb45732fcb3145f822a2b0b8b9ebb6fc42f3824d1f56ac6fb37c77e84f50af5bfc949262e596d633c4bf30d7cd5d88b13fd9c9a2f19485

dev-python/pdm/pdm-2.7.1.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit bash-completion-r1 distutils-r1 pypi
+
+DESCRIPTION="Modern Python package and dependency manager supporting latest PEP standards"
+HOMEPAGE="
+	https://github.com/pdm-project/pdm/
+	https://pypi.org/project/pdm/
+"
+
+LICENSE="MIT"
+KEYWORDS="~amd64"
+SLOT="0"
+
+RDEPEND="
+	dev-python/blinker[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+	dev-python/requests-toolbelt[${PYTHON_USEDEP}]
+	>=dev-python/unearth-0.9.0[${PYTHON_USEDEP}]
+	dev-python/findpython[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+	dev-python/shellingham[${PYTHON_USEDEP}]
+	dev-python/python-dotenv[${PYTHON_USEDEP}]
+	dev-python/resolvelib[${PYTHON_USEDEP}]
+	dev-python/installer[${PYTHON_USEDEP}]
+	dev-python/cachecontrol[${PYTHON_USEDEP}]
+
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/pytest-httpserver[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_compile_all() {
+	PDM_CHECK_UPDATE=0 "${EPYTHON}" -m pdm completion bash > completion.bash || die
+	PDM_CHECK_UPDATE=0 "${EPYTHON}" -m pdm completion zsh > completion.zsh || die
+}
+
+python_test() {
+	epytest -m "not network"
+
+	# clear saved python version
+	rm -f .pdm-python
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newbashcomp completion.bash pdm
+
+	insinto /usr/share/zsh/site-functions
+	newins completion.zsh _pdm
+}