gui-wm/phoc: add 0.47.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

gui-wm/phoc/Manifest

@@ -10,3 +10,5 @@ DIST phoc-0.45.0.tar.xz 721780 BLAKE2B 0409e8b74f18fa3f5dab942d090312bad11c1dfd6
 DIST phoc-0.45.0.tar.xz.asc 833 BLAKE2B aa46dbc6ebe74d748f276f86c28a15f49721509d4ad8d3bd20e57d7c9ce6471cbc792f1eab8b4e7cc80f7a0f67c5ba97d5e12a2f09dbe8c22574b51f50c9aae9 SHA512 3ec861c7d8e6407e6e99d585033bd84ab2ac4513de2e023ac02cecafa3d1e8889c6da9ea20096c4f056d94d0044ec4ec938252d25971ca5c86f0658e9d5baabb
 DIST phoc-0.46.0.tar.xz 730608 BLAKE2B 51716b99447c0275bdc3af0bd6587c53c240612f659d2d69257b717bd2323515b80367f8d92adc9c89297c87c6dede4c51a011e77f950dfb09ece55e14e55d7a SHA512 cb089a48dd12e2885fa7fa23df62b4ee60f3701900327195f74afda528cc736322e7f29440fcff5fa81cfebf6ffcffee5c4b67a127823b438da577d3fc3c3747
 DIST phoc-0.46.0.tar.xz.asc 833 BLAKE2B c7f2fe56f4fb085160d968bda21d47574ef4decb145c4e08f6f9b337a28dabaab52efb306eab1e09646420553f49804e58cfe4aed70973c4f83dacee63985edb SHA512 29c67a5b6dbc1420e47ab7853d4c19a255eeaf09c1ef0bc3920e48c74feeae20d864a335e76d71178ab95f27127ad3b2a362ba10d3bad18ad834f4a6527031c7
+DIST phoc-0.47.0.tar.xz 732348 BLAKE2B 1558858760f56bb6a693d261807beae3d30e3c6296a52e42bb73c51963e92a710b13a060a0b87e216fb09899f1ce879518a5110c7c409f43d8e00885b572b92e SHA512 b36c413edea91fa5bde2fb8f7761f2fb9f5ad5f546da4d712dce90a083300e99d902b43e38268a87922870296f705bae8402fc81d95f83f866956cf33ecbf00c
+DIST phoc-0.47.0.tar.xz.asc 833 BLAKE2B 96f0641c5ea0f53154fef331359f0ce8b7f408dddc56270f82397d9d91656f5411c2c712db5733c46f60b5459f8fb140105c301631e4d56817f177c5a8b9d39d SHA512 3eca2f2cc5a208dd6f61a91dbd2c9649078224eee1ba9aa797624c86b2a36872c962a4355b744660b629362ba6cfbe77e855a168867ae5e39456e77051784a82

gui-wm/phoc/phoc-0.47.0.ebuild

@@ -0,0 +1,122 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson verify-sig virtualx xdg
+
+DESCRIPTION="Wayland compositor for mobile phones"
+HOMEPAGE="https://gitlab.gnome.org/World/Phosh/phoc"
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
+	verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )
+"
+
+LICENSE="|| ( GPL-3+ MIT ) GPL-3+ LGPL-2.1+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="gtk-doc man test"
+RESTRICT="!test? ( test )"
+
+WLROOTS_RDEPEND="
+	>=dev-libs/libinput-1.19.0:=
+	>=dev-libs/libliftoff-0.4
+	>=dev-libs/wayland-1.23.0
+	media-libs/libdisplay-info:=
+	media-libs/libglvnd
+	media-libs/vulkan-loader
+	|| (
+		>=media-libs/mesa-24.1.0_rc1[opengl]
+		<media-libs/mesa-24.1.0_rc1[egl(+),gles2]
+	)
+	sys-apps/hwdata
+	sys-auth/seatd:=
+	x11-base/xwayland
+	x11-libs/cairo
+	>=x11-libs/libdrm-2.4.122
+	x11-libs/libxcb:=
+	>=x11-libs/pixman-0.42.0
+	x11-libs/xcb-util-errors
+	x11-libs/xcb-util-renderutil
+	x11-libs/xcb-util-wm
+	virtual/libudev:=
+"
+WLROOTS_DEPEND="
+	dev-util/vulkan-headers
+	x11-libs/libxkbcommon
+"
+WLROOTS_BDEPEND="
+	dev-util/glslang
+"
+
+RDEPEND="${WLROOTS_RDEPEND}
+	>=dev-libs/glib-2.80:2
+	dev-libs/gmobile
+	dev-libs/libinput:=
+	dev-libs/wayland
+	>=gnome-base/gnome-desktop-3.26:3=
+	gnome-base/gsettings-desktop-schemas
+	>=x11-libs/pixman-0.43.4
+	x11-libs/libxcb:=
+	x11-libs/libxkbcommon
+"
+DEPEND="${WLROOTS_DEPEND}
+	${RDEPEND}
+	test? ( x11-wm/mutter )
+"
+BDEPEND="${WLROOTS_BDEPEND}
+	dev-libs/glib:2
+	dev-libs/wayland-protocols
+	dev-util/wayland-scanner
+	sys-devel/gettext
+	gtk-doc? ( dev-util/gi-docgen )
+	man? ( dev-python/docutils )
+	verify-sig? ( sec-keys/openpgp-keys-phosh )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
+
+src_prepare() {
+	default
+
+	cd subprojects/wlroots || die
+	eapply "${S}"/subprojects/packagefiles/wlroots
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man)
+		$(meson_use test tests)
+		-Ddefault_library=static
+		-Dembed-wlroots=enabled
+		-Dxwayland=enabled
+	)
+	meson_src_configure
+}
+
+src_test() {
+	local -x LC_ALL="C.UTF-8"
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install --skip-subprojects wlroots
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+
+	newbin helpers/auto-maximize phoc-auto-maximize
+	newbin helpers/scale-to-fit phoc-scale-to-fit
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}