From 1e864dac04d2d9e0ec90856d5471c8397242924a Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Matt=C3=A9o=20Rossillol=E2=80=91=E2=80=91Laruelle?=
 <beatussum@protonmail.com>
Date: Sun, 8 Jun 2025 14:19:33 +0200
Subject: [PATCH] net-misc/ffsend: add 9999
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Mattéo Rossillol‑‑Laruelle <beatussum@protonmail.com>
---
 net-misc/ffsend/ffsend-0.2.77.ebuild | 25 ++++++++---
 net-misc/ffsend/ffsend-9999.ebuild   | 64 ++++++++++++++++++++++++++++
 2 files changed, 84 insertions(+), 5 deletions(-)
 create mode 100644 net-misc/ffsend/ffsend-9999.ebuild

diff --git a/net-misc/ffsend/ffsend-0.2.77.ebuild b/net-misc/ffsend/ffsend-0.2.77.ebuild
index 21983926cf..7f2c6a3c69 100644
--- a/net-misc/ffsend/ffsend-0.2.77.ebuild
+++ b/net-misc/ffsend/ffsend-0.2.77.ebuild
@@ -10,10 +10,17 @@ inherit cargo optfeature shell-completion
 DESCRIPTION="Easily and securely share files from the command line"
 HOMEPAGE="https://timvisee.com/projects/ffsend/"
 
-SRC_URI="
-	https://github.com/timvisee/ffsend/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
-	https://github.com/beatussum/gentoo-tarballs/releases/download/latest/${P}-crates.tar.xz
-"
+if [[ "${PV}" = "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/timvisee/ffsend.git"
+else
+	SRC_URI="
+		https://github.com/timvisee/ffsend/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
+		https://github.com/beatussum/gentoo-tarballs/releases/download/latest/${P}-crates.tar.xz
+	"
+
+	KEYWORDS="~amd64"
+fi
 
 LICENSE="GPL-3"
 
@@ -21,7 +28,6 @@ LICENSE="GPL-3"
 LICENSE+=" Apache-2.0 BSD-2 BSD ISC MIT MPL-2.0 Unicode-DFS-2016"
 
 SLOT="0"
-KEYWORDS="~amd64"
 
 DOCS=(
 	res/
@@ -30,6 +36,15 @@ DOCS=(
 	SECURITY.md
 )
 
+src_unpack() {
+	if [[ "${PV}" = "9999" ]]; then
+		git-r3_src_unpack
+		cargo_live_src_unpack
+	else
+		cargo_src_unpack
+	fi
+}
+
 src_install() {
 	einstalldocs
 	cargo_src_install
diff --git a/net-misc/ffsend/ffsend-9999.ebuild b/net-misc/ffsend/ffsend-9999.ebuild
new file mode 100644
index 0000000000..7f2c6a3c69
--- /dev/null
+++ b/net-misc/ffsend/ffsend-9999.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Autogenerated by pycargoebuild 0.14.0
+
+EAPI=8
+
+inherit cargo optfeature shell-completion
+
+DESCRIPTION="Easily and securely share files from the command line"
+HOMEPAGE="https://timvisee.com/projects/ffsend/"
+
+if [[ "${PV}" = "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/timvisee/ffsend.git"
+else
+	SRC_URI="
+		https://github.com/timvisee/ffsend/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
+		https://github.com/beatussum/gentoo-tarballs/releases/download/latest/${P}-crates.tar.xz
+	"
+
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+
+# Dependent crate licenses
+LICENSE+=" Apache-2.0 BSD-2 BSD ISC MIT MPL-2.0 Unicode-DFS-2016"
+
+SLOT="0"
+
+DOCS=(
+	res/
+	CONTRIBUTING.md
+	README.md
+	SECURITY.md
+)
+
+src_unpack() {
+	if [[ "${PV}" = "9999" ]]; then
+		git-r3_src_unpack
+		cargo_live_src_unpack
+	else
+		cargo_src_unpack
+	fi
+}
+
+src_install() {
+	einstalldocs
+	cargo_src_install
+
+	newbashcomp contrib/completions/ffsend.bash ffsend
+	dofishcomp contrib/completions/ffsend.fish
+	dozshcomp contrib/completions/_ffsend
+
+	exeinto /usr/share/nautilus-script
+	doexe contrib/util/nautilus/firefox-send
+}
+
+pkg_postinst() {
+	optfeature "the Nautilus script support" \
+		"gnome-base/nautilus" \
+		"gnome-extra/zenity"
+}