app-text/OCRmyPDF: add 14.1.0

Closes: https://bugs.gentoo.org/881703
Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

app-text/OCRmyPDF/Manifest

@@ -1 +1,2 @@
 DIST OCRmyPDF-14.0.1.tar.gz 6502713 BLAKE2B fc0a1b681bbc25f091f2262ec00c9ed638e38fae9042a1fa50efaff2af915279dffd6fb9b8db73dbced2adfb8d8bf4e66417f9cb5f6dd80c78a842bf6d20fbdd SHA512 371e53bc6ff272b9b34029c7dad78e453d20c77995b5d61ceddac3b92f5f9496be726c8da8a07c75504a2a7626ba8cefb2f2d6e8288e093d5fd95ecd4546c8ce
+DIST OCRmyPDF-14.1.0.tar.gz 6508692 BLAKE2B cb9eb2a782c0640d149047190c5d92a1cf6c183346ae34f0663c26b5d5ddba9bd7c1796c390d805c29443ef04e2d2c1cf7228469d4d3ee4fc0bf7e67214b084d SHA512 f68049e14416eb9b4a28436935c70b674e8dbe1c529d94c3a0b95e1d56f7b8e785ca29daf1183323510786bb04b2b9e963ff9021d3acab73aff5ff88393eb8d3

app-text/OCRmyPDF/OCRmyPDF-14.1.0.ebuild

@@ -0,0 +1,68 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1 optfeature shell-completion
+
+DESCRIPTION="OCRmyPDF adds an OCR text layer to scanned PDF files"
+HOMEPAGE="https://github.com/ocrmypdf/OCRmyPDF"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-SA-2.5 CC-BY-SA-4.0 MIT MPL-2.0 ZLIB"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=app-text/ghostscript-gpl-9.50
+	>=app-text/pdfminer-20201018[${PYTHON_USEDEP}]
+	>=app-text/tesseract-4.1.1[jpeg,tiff,png,webp]
+	>=dev-python/coloredlogs-14.0[${PYTHON_USEDEP}]
+	>=dev-python/deprecation-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20[${PYTHON_USEDEP}]
+	>dev-python/pikepdf-5.0.1[${PYTHON_USEDEP}]
+	>=dev-python/pillow-8.2.0[lcms,${PYTHON_USEDEP}]
+	>=dev-python/pluggy-0.13.0[${PYTHON_USEDEP}]
+	>=dev-python/reportlab-3.5.66[${PYTHON_USEDEP}]
+	>=dev-python/tqdm-4[${PYTHON_USEDEP}]
+	>=media-gfx/img2pdf-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		>=app-text/unpaper-6.1
+		dev-python/pytest-helpers-namespace[${PYTHON_USEDEP}]
+		>=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+		>=media-libs/jbig2enc-0.29
+		>=media-gfx/pngquant-2.5
+	)
+"
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-issues \
+	dev-python/sphinx-rtd-theme
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+	distutils-r1_src_prepare
+	sed -e "/-n auto/d" -i pyproject.toml || die
+}
+
+src_install() {
+	distutils-r1_src_install
+	newbashcomp misc/completion/ocrmypdf.bash "${PN,,}"
+
+	dofishcomp misc/completion/ocrmypdf.fish
+}
+
+pkg_postinst() {
+	optfeature "JBIG2 optimization support" media-libs/jbig2enc
+	optfeature "image cleaning support" app-text/unpaper
+	optfeature "PNG optimization support" media-gfx/pngquant
+}